Answer time measurement experiment

Reply

AMI_Hamburg Posted: 09-01-2010 4:38 AM

rated by 0 users

I want to program an experiment to get the generell reaction time of my probands. They need to click on "e" or "i" randomly to start the time measurement and to stop it with a second click. This procedure should we replictaed 10 till 15 times. This experiment should measure how fast the probands are able to click and to get a proxy of there "hidden" latency.

I realized a first version - but I want to realize these "Start-Stop" combination with each click. I do not get it run. Additionally I want to integrate a visualization/display of the reaction time on the screen instantly.

Is it possible to realize this and how?

Thanks a lot in advance for your help

Cheers

Daniel

Reply

Dave replied on 09-01-2010 5:06 AM

rated by 0 users

<defaults>
/ inputdevice = mouse
/ txcolor = (white)
/ txbgcolor = (black)
/ fontstyle = ("Verdana", 2.5%, true)
</defaults>

<block myblock>
/ trials = [1-10=sequence(start, stop); 11=report]
</block>

<trial start>
/ stimulusframes = [1=start, rtinfo]
/ validresponse = (start)
</trial>

<trial stop>
/ stimulusframes = [1=stop, rtinfo]
/ validresponse = (stop)
</trial>

<trial report>
/ stimulusframes = [1=end, rtinfo]
/ validresponse = (end)
</trial>

<text start>
/ items = ("START")
/ position = (50%, 50%)
/ size = (25%, 5%)
/ vjustify = center
/ erase = false
</text>

<text stop>
/ items = ("STOP")
/ position = (50%, 50%)
/ vjustify = center
/ size = (25%, 5%)
/ erase = false
</text>

<text end>
/ items = ("END")
/ position = (50%, 50%)
/ vjustify = center
/ size = (25%, 5%)
/ erase = false
</text>

<text rtinfo>
/ items = ("Last RT = <%trial.stop.latency%> | Sum RT = <%trial.stop.sumlatency%> | N = <%trial.stop.count%>
Mean RT = <%trial.stop.meanlatency%> | SD RT = <%trial.stop.sdlatency%>")
/ vjustify = center
/ size = (80%, 10%)
/ position = (50%, 10%)
/ erase = false
</text>

Regards,

~Dave