Millisecond Online Community

Hi,
I´ve been trying to make Inquisit send markers to biopac. It´s two (randomized) stimuli that need to send two differend markers everytime they appear.
I will probably use three different channels on biopac per subject.
Can anyone tell me how to program that?
Thanks:)!

I think there are several ways to do this depending on your overall design. Here's one example of how to do this *in principle*:

<trial exampletrial>
/ stimulusframes = [1=stimuli, biopac]
/ validresponse = ("A", "B")
</trial>

<text stimuli>
/ items = ("Stimulus A", "Stimulus B")
/ select = replace
</text>

<port biopac>
/ port = LPT1
/ subport = data
/ items = ("00000001", "00000010")
/ erase = ("00000000")
/ select = current(stimuli)
</port>

If your two stimuli are presented by separate trials, you could do something like this:

<trial stimulus_a>
/ stimulusframes = [1=stimulus_a, biopac_a]
/ validresponse = ("A", "B")
/ correctresponse = ("A")
</trial>

<trial stimulus_b>
/ stimulusframes = [1=stimulus_b, biopac_b]
/ validresponse = ("A", "B")
/ correctresponse = ("B")
</trial>

<port biopac_a>
/ port = LPT1
/ subport = data
/ items = ("00000001")
/ erase = ("00000000")
</port>

<port biopac_b>
/ port = LPT1
/ subport = data
/ items = ("00000010")
/ erase = ("00000000")
</port>

<text stimulus_a>
/ items = ("Stimulus A")
</text>

<text stimulus_b>
/ items = ("Stimulus B")
</text>

This thread (link) might also be helpful.

Best,
~Dave