---------------------------------------------------------------------------------------
*** DEFAULTS *****
---------------------------------------------------------------------------------------			

<defaults>
/ screencolor = (175, 175, 200)
/ font = ("Arial", -21, 700, 0, 34)
/ txcolor = (0, 0, 0)
/ txbgcolor = (175, 175, 200)
/ validresponse = ("E", " ", "I")
/ pretrialpause = 200
/ posttrialpause = 200
</defaults>

<data>
/ columns = [date subject blocknum blockcode trialnum trialcode latency response correct stimulusnumber stimulusitem stimulusnumber stimulusitem]
</data>


------------------------------------------------------------------------------------
*** TEXTS AND targetS *****
------------------------------------------------------------------------------------

<page attributePractice>
^For the upcoming sorting task you will be classifying words as indicating the concepts of 'Positive' or 'Negative'.^^For that task, please judge each word on the basis of which concept ('Positive' or 'Negative') it belongs with.^
</page>

<text attrleft> 
/ items = ("Positive")
/ font = ("Arial", -40, 700, 0, 34)
/ position = (25, 17)
</text>

<text attrright> 
/ font = ("Arial", -40, 700, 0, 34)
/ items = ("Negative")
/ position = (75, 17)
</text>

<text attrL>
/ items = attrL
/ font = ("Arial", -48, 700, 0, 34)
</text>

<item attrL>
/ 1 = "love"
/ 2 = "peace"
/ 3 = "happiness"
/ 4 = "joy"
/5 = "flower"
</item>

<text attrR>
/ items = attrR
/ font = ("Arial", -48, 700, 0, 34)
</text>

<item attrR>
/ 1 = "hatred"
/ 2 = "death"
/ 3 = "war"
/ 4 = "pain"
/ 5 = "murder"
</item>

<text targ1left> 
/ items = ("Animal")
/ font = ("Arial", -40, 700, 0, 34)
/ position = (25, 30)
</text>

<text targ1right> 
/ items = ("Animal")
/ font = ("Arial", -40, 700, 0, 34)
/ position = (75, 30)
</text>

<text targ1>
/ items = targ1
/ font = ("Arial", -48, 700, 0, 34)
/ erase = true (175, 175, 200)
/ color = (0,0,0)
/ numitems = 5
/ txbgcolor = (175, 175, 200)
</text>

<Item targ1>
/ 1 = "sheep"
/ 2 = "horse"
/ 3 = "bug"
/ 4 = "cat"
/ 5 = "dog"
</item>

 ******** First, utility items ********

<text blank>
/ erase = false
/ items = (" ")
</text>

<text error>
/ items = ("X")
/ font = ("Arial", -48, 700, 0, 34)
/ position = (50,60)
</text>

******* Reminder Stimuli for Block Backgrounds *******
<text SPACEBAR>
/ items = ("READ INSTRUCTIONS ABOVE, THEN PRESS SPACE BAR TO START")
/ position = (50,60)
/ font = ("Arial", -17, 700, 0, 34)
/ color = (255,0,0)
</text>

<text PRACTICE>
/ items = ("THIS IS PRACTICE -- TRY TO MAKE FEW ERRORS")
/ position = (50,50)
/ font = ("Arial", -19, 700, 0, 34)
/ color = (200,55,55)
</text>

<text TEST>
/ items = ("THIS IS TEST -- GO FAST, MAKING A FEW ERRORS IS OK")
/ position = (50,50)
/ font = ("Arial", -19, 700, 0, 34)
/ color = (255,0,0)
</text>

<text FEEDBACK1>
/ items = ("IF YOU MAKE AN ERROR YOU WILL SEE A BLACK 'X'")
/ font = ("Arial", -19, 700, 0, 34)
/ position = (50,35)
</text>

<text FEEDBACK2>
/ items = ("BELOW THE STIMULUS -- WHEN THIS HAPPENS,")
/ font = ("Arial", -19, 700, 0, 34)
/ position = (50,40)
</text>

<text FEEDBACK3>
/ items = ("YOU HAVE TO MAKE THE CORRECT RESPONSE TO PROCEED")
/ font = ("Arial", -19, 700, 0, 34)
/ position = (50,45)
</text>

<text FEEDBACK4>
/ items = ("YOU WILL NOW GET NO INDICATION OF ERRORS,")
/ font = ("Arial", -19, 700, 0, 34)
/ position = (50,37)
</text>

<text FEEDBACK5>
/ items = ("SO MAKE ONLY ONE RESPONSE TO EACH STIMULUS")
/ font = ("Arial", -19, 700, 0, 34)
/ position = (50,42)
</text>

<text FEEDBACK4x>
/ items = ("YOU WILL NOW GET NO INDICATION OF ERRORS,")
/ font = ("Arial", -19, 700, 0, 34)
/ position = (50,37)
/ color = (128,128,128)
</text>

<text FEEDBACK5x>
/ items = ("SO MAKE ONLY ONE RESPONSE TO EACH STIMULUS")
/ font = ("Arial", -19, 700, 0, 34)
/ position = (50,42)
/ color = (128,128,128)
</text>

<text instrE>
/ font = ("Arial", -27, 700, 0, 34)
/ items = ("PRESS 'E' FOR")
/ position = (25, 10)
/ color = (128,128,128)
</text>

<text instrI>
/ font = ("Arial", -27, 700, 0, 34)
/ items = ("PRESS 'I' FOR")
/ position = (75, 10)
/ color = (128,128,128)
</text>

<text ORleft>
/ items = ("OR")
/ font = ("Arial", -30, 700, 0, 34)
/ position = (25, 23)
/ color = (128,128,128)
</text>

<text ORright>
/ items = ("OR")
/ font = ("Arial", -30, 700, 0, 34)
/ position = (75, 23)
/ color = (128,128,128)
</text>


------------------------------------------------------------------------------------
*** INSTRUCTION PAGES *****
------------------------------------------------------------------------------------

<instruct> 
/ font = ("Arial", -18, 400, 0, 34)
/ nextkey = (" ")
/ nextlabel = "Press space bar to proceed"
/ lastlabel = "Press space bar to proceed"
/ prevkey = ("E")
/ screencolor = (233, 233, 239)
</instruct>

<page begin1>
^This demonstration of the Implicit Association Test (IAT) asks you to sort words into different categories.^Average time for the entire demonstration is 6 minutes.^^INSTRUCTIONS FOR THE SORTING TASKS^^For each of several sorting tasks you will be shown words one at a time in the middle of the computer screen.Your task is to sort each word into its correct category by pressing EITHER the‘E’ key or the ‘I’ key.^^IMPORTANT: Press the ‘E’ key using your left index finger, or the ‘I’ key using your right index finger.^^The categories associated with the ‘E’ and ‘I’ keys will be shown at the top of each screen. Please pay close attention to these category labels -- they change for each sorting task!
</page>

<page practice1>
^The upcoming block is practice. Use these trials to make sure you understand the task instructions.^
</page>

<page practice2>
^The upcoming block is practice. This practice block will be lengthened because of the difficulty added by your having to reverse the previous instructions.
</page>

<page test>
^The upcoming block is for data collection. Please try to go as fast as you can.^It is OK to make errors, although you should try not to make more than a few.^
</page>

<PAGE end> 
^The Implicit Association Test demonstration is now completed.^Thank you for participating.
</page>

------------------------------------------------------------------------------------
*** TRIALS *****
------------------------------------------------------------------------------------

<trial practice>
/ correctresponse = (" ")
/ stimulusframes = [1=practice]
/ responsemode = correct
/ pretrialpause = 500
/ posttrialpause = 500
/ correctmessage = false
/ errormessage = false
</trial>

<trial test>
/ correctresponse = (" ")
/ stimulusframes = [1=test]
/ responsemode = correct
/ pretrialpause = 500
/ posttrialpause = 500
/ correctmessage = false
/ errormessage = false
</trial>

<trial attrleft>
/ correctresponse = ("E")
/ stimulusframes = [1=BLANK,attrL]
</trial>

<trial attrright>
/ correctresponse = ("I")
/ stimulusframes = [1=BLANK,attrR]
</trial>

<trial targ1left>
/ correctresponse = ("E")
/ stimulusframes = [1=BLANK,targ1]
</trial>

<trial targ1right>
/ correctresponse = ("I")
/ stimulusframes = [1=BLANK,targ1]
</trial>


------------------------------------------------------------------------------------
*** BLOCKS *****
------------------------------------------------------------------------------------

<block attribprepractice>
/ bgstim = (SPACEBAR, instrE, instrI, attrleft, attrright, FEEDBACK1, FEEDBACK2, FEEDBACK3)
/ preinstructions = (attributePractice)
/ trials = [1=practice]
/ responsemode = correct
</block>

<block attribpractice>
/ blockfeedback = (correct) 
/ bgstim = (instrE, instrI, attrleft, attrright)
/ trials = [1-20 = random(attrleft, attrright)]
/ errormessage = true(error,200)
/ responsemode = correct
</block>

<block compatprepractice1>
/ preinstructions = (practice1)
/ bgstim = (SPACEBAR, instrE, instrI, attrleft, targ1left, ORleft, ORright, attrright)
/ trials = [1=practice]
/ responsemode = correct
</block>

<block compatprepractice2>
/ preinstructions = (practice2)
/ bgstim = (SPACEBAR, instrE, instrI, attrleft, targ1left, ORleft, ORright, attrright)
/ trials = [1=practice]
/ responsemode = correct
</block>

<block compatpractice1>
/ bgstim = (attrleft, targ1left, ORleft, attrright)
/ trials = [1-24=noreplace(attrright, attrleft, targ1left)]
/ errormessage = true(error,200)
/ responsemode = correct
</block>

<block compatpractice2>
/ bgstim = (attrleft, targ1left, ORleft,  attrright)
/ trials = [1-36 = noreplace(attrright, attrleft, targ1left)]
/ errormessage = true(error,200)
/ responsemode = correct
</block>

<block compatpretest>
/ bgstim = (SPACEBAR, instrE, instrI, attrleft, ORleft, targ1left, attrright)
/ preinstructions = (test)
/ trials = [1=test]
/ responsemode = correct
</block>

<block compattest>
/ bgstim = (attrleft, targ1left, ORleft, attrright)
/ trials = [1-40 = noreplace(attrright, attrleft, targ1left)]
/ errormessage = true(error,200)
/ responsemode = correct
</block>

<block noncompatprepractice1>
/ preinstructions = (practice1)
/ bgstim = (SPACEBAR, instrE, instrI, attrleft, ORright, attrright, targ1right)
/ trials = [1=practice]
/ responsemode = correct
</block>

<block noncompatprepractice2>
/ preinstructions = (practice2)
/ bgstim = (SPACEBAR, instrE, instrI, attrleft, ORright, attrright, targ1right)
/ trials = [1=practice]
/ responsemode = correct
</block>

<block noncompatpractice1>
/ bgstim = (attrleft, ORright, attrright, targ1right)
/ trials = [1-24 = noreplace(targ1right, attrleft, attrright)]
/ errormessage = true(error,200)
/ responsemode = correct
</block>

<block noncompatpractice2>
/ bgstim = (attrleft, ORright, attrright, targ1right)
/ trials = [1-36 = noreplace(attrleft, targ1right, attrright)]
/ errormessage = true(error,200)
/ responsemode = correct
</block>

<block noncompatpretest>
/ bgstim = (SPACEBAR, instrE, instrI, attrleft,  ORright, attrright, targ1right)
/ preinstructions = (test)
/ trials = [1=test]
/ responsemode = correct
</block>

<block noncompattest>
/ bgstim = (attrleft, ORright, attrright, targ1right)
/ trials = [1-40 = noreplace(attrleft, targ1right, attrright)]
/ errormessage = true(error,200)
/ responsemode = correct
</block>

------------------------------------------------------------------------------------
*** EXPERIMENT*****
------------------------------------------------------------------------------------

<expt>
/ subjects = (1 of 2)
/ preinstructions = (begin1)
/ postinstructions = (end)
/ blocks = [
 1=attribprepractice; 
 2=attribpractice; 
 3=noncompatprepractice1;
 4=noncompatpractice1; 
 5=noncompatpretest;
 6=noncompattest;
 7=compatprepractice2;
 8=compatpractice2; 
 9=compatpretest;
 10=compattest
]</expt>

<expt>
/ subjects = (2 of 2)
/ preinstructions = (begin1)
/ postinstructions = (end)
/ blocks = [
 1=attribprepractice;
 2=attribpractice; 
 3=compatprepractice1;
 4=compatpractice1; 
 5=compatpretest;
 6=compattest;
 7=noncompatprepractice2;
 8=noncompatpractice2;
 9=noncompatpretest;
 10=noncompattest]
</expt>