**************************************************************************************************************
**************************************************************************************************************
	Information Sampling Task (IST)
**************************************************************************************************************
**************************************************************************************************************

	This script implements the 'Information Sampling Task' (IST) as described in:

	Clark, L., Robbins, T.W., Ersche, K.D., & Sahakian, B.J. (2006). Reflection impulsivity in 
	current and former substance users. Biological Psychiatry, 60, 515-522.

**************************************************************************************************************
**************************************************************************************************************
	Script Version:	0.9a (Beta)
	Last Modified:	09-15-2009 at 02:02 AM (GMT+1)
**************************************************************************************************************
**************************************************************************************************************

	Inquisit programming: 
	David Nitz (nitz.david@gmail.com)
	for Millisecond Software, LLC.
		
	This script requires Inquisit 3.0.4.0 or greater.
	Copyright (c) 2009 by Millisecond Software, LLC.
	http://www.millisecond.com/

**************************************************************************************************************
**************************************************************************************************************
	Editable Task Parameters
**************************************************************************************************************
**************************************************************************************************************

	win_dw:					maximum points to be won per round in the 'Decreasing Win' condition
	win_fw:					maximum points to be won per round in the 'Fixed Win' condition
	decrement_dw:		decrement in points per uncovered square in the 'Decreasing Win' condition
	nrounds_dw:			number of rounds in the 'Decreasing Win' condition
	nrounds_fw:			number of rounds in the 'Fixed Win' condition
	nrounds_prac:			number of practice rounds
	totalpoints:			amount of points at the start of the task

**************************************************************************************************************
**************************************************************************************************************
	The remaining entries are updated at runtime / used for data recording and should *not* be 
	changed, unless you really know what you are doing. Entries of interest are explained below.
**************************************************************************************************************
**************************************************************************************************************
	
	color1:					color value assigned to color1 in a given round
	color2:					color value assigned to color2 in a given round
	ncolor1:					number of color1 squares in a given round
	ncolor2:					number of color2 squares in a given round
	npicks:					total number of uncovered squares in a given round
	color1pick:				number of uncovered color1 squares in a given round
	color2pick:				number of uncovered color1 squares in a given round
	decision:				'correct' if the participant makes a correct decision
								'wrong' if the participant makes an incorrect decision

**************************************************************************************************************
**************************************************************************************************************
<values>
/ win_dw = 250
/ win_fw = 100
/ win = 0
/ lose = 100
/ currentwin = 0
/ totalpoints = 100
/ decrement = 0
/ decrement_dw = 10
/ nrounds_fw = 10
/ nrounds_dw = 10
/ nrounds_prac = 1
/ nrounds = 0
/ roundcount = 0
/ color1 = 0
/ color2 = 0
/ ncolor1 = 0
/ ncolor2 = 0
/ npicks = 0
/ color1pick = 0
/ color2pick = 0
/ decision = ""
/ responsestorage = ""
/ feedbackswitch = 1
/ stopblock = 0
</values>

**************************************************************************************************************
**************************************************************************************************************
	Custom Data Output
**************************************************************************************************************
**************************************************************************************************************
<data IST>
/ columns = [date, time, subject, blocknum, blockcode, trialnum, trialcode, latency, response,
	values.roundcount, values.color1, values.ncolor1, values.color2, values.ncolor2,
	values.npicks, values.color1pick, values.color2pick, values.decision, values.totalpoints]
/ separatefiles = true
</data>

**************************************************************************************************************
**************************************************************************************************************
	Task Instructions
**************************************************************************************************************
**************************************************************************************************************
<instruct IST>
/ fontstyle = ("Verdana", 3.0%, false, false, false, false, 5, 0)
/ windowsize = (80%, 80%)
/ prevlabel = "Go back..."
/ nextlabel = "Click here!"
/ finishlabel = "Click here!"
</instruct>

<page welcome>
^Welcome to the Information Sampling Task!
^^You are about to play a game for points. The game will take 10 minutes to complete.
It consists of two parts and on each part there will be 10 gos.
^^On every go, you will be able to see 25 boxes on the screen. Initially, the boxes will all be
greyed out, but when you pick a box, it will reveal itself to be one of two colors.
^^Your task is to decide which color you think is in the majority. It is entirely up to you how
many boxes you open before making your decision. When you have made your decision, you
should click on the respective color panel at the bottom of the screen.
</page>

<page instr_prac_fw>
^^On the following go, you will win 100 points if you pick the correct color, regardless of how
many boxes you open, and you can open as many boxes as you wish. You will lose 100 points
if you get it wrong. 
^^Try to win as many points as you can.
</page>

<page instr_fw>
^^On the following <%values.nrounds_fw%> gos, you will win 100 points if you pick the correct
color, regardless of how many boxes you open, and you can open as many boxes as you wish.
You will lose 100 points if you get it wrong. 
^^Try to win as many points as you can.
</page>

<page instr_dw>
^^On these <%values.nrounds_dw%> gos, the amount you can win will drop by 10 points with
every box you uncover, therefore the earlier you make your decision the more points you will
win if you are right. If you are wrong, you will lose 100 points regardless of when you make
your decision.
^^Try to win as many points as you can.
</page>

<page end>
^^This concludes the Information Sampling Task.
^^Thanks for participating!
</page>

**************************************************************************************************************
**************************************************************************************************************
	Block Definitions
**************************************************************************************************************
**************************************************************************************************************
	Practice Block (Fixed Win Condition)
**************************************************************************************************************
**************************************************************************************************************
<block Prac_IST_FW>
/ onblockbegin = [if(script.subjectid == "debug"){
	text.ncolor1.textcolor = white; text.ncolor2.textcolor = white;
	text.color1pick.textcolor = white; text.color2pick.textcolor = white;
	text.roundcount.textcolor = white}]
/ onblockbegin = [values.stopblock = 0; values.decrement = 0; values.currentwin = values.win_fw; 
	values.nrounds = values.nrounds_prac; values.roundcount = 0]
/ stop = [values.stopblock == 1]
/ trials = [1=selectcolor]
/ preinstructions = (instr_prac_fw)
/ recorddata = false
</block>

**************************************************************************************************************
**************************************************************************************************************
	Test Block FW (Fixed Win Condition)
**************************************************************************************************************
**************************************************************************************************************
<block Test_IST_FW>
/ onblockbegin = [if(script.subjectid == "debug"){
	text.ncolor1.textcolor = white; text.ncolor2.textcolor = white;
	text.color1pick.textcolor = white; text.color2pick.textcolor = white;
	text.roundcount.textcolor = white}]
/ onblockbegin = [values.stopblock = 0; values.decrement = 0; values.currentwin = values.win_fw; 
	values.nrounds = values.nrounds_fw; values.roundcount = 0]
/ stop = [values.stopblock == 1]
/ trials = [1=selectcolor]
/ preinstructions = (instr_fw)
</block>

**************************************************************************************************************
**************************************************************************************************************
	Test Block FW (Decreasing Win Condition)
**************************************************************************************************************
**************************************************************************************************************
<block Test_IST_DW>
/ onblockbegin = [if(script.subjectid == "debug"){
	text.ncolor1.textcolor = white; text.ncolor2.textcolor = white;
	text.color1pick.textcolor = white; text.color2pick.textcolor = white;
	text.roundcount.textcolor = white}]
/ onblockbegin = [values.stopblock = 0; values.decrement = values.decrement_dw; 
	values.currentwin = values.win_dw; values.nrounds = values.nrounds_dw; 
	values.roundcount = 0]
/ stop = [values.stopblock == 1]
/ trials = [1=selectcolor]
/ preinstructions = (instr_dw)
</block>

**************************************************************************************************************
**************************************************************************************************************
	Experiment Definitions	
**************************************************************************************************************
**************************************************************************************************************
	Order of conditions (FW/DW) is counterbalanced across subjects:
	IST1 -> 'Fixed Win' first for odd-numbered subjects.
	IST2 -> 'Decreasing Win' first for even-numbered subjects.
**************************************************************************************************************
**************************************************************************************************************
<expt IST1>
/ subjects = (1 of 2)
/ blocks = [1=Prac_IST_FW; 2=Test_IST_FW; 3=Test_IST_DW]
/ preinstructions = (welcome)
/ postinstructions = (end)
</expt>

<expt IST2>
/ subjects = (2 of 2)
/ blocks = [1=Prac_IST_FW; 2=Test_IST_DW; 3=Test_IST_FW]
/ preinstructions = (welcome)
/ postinstructions = (end)
</expt>

**************************************************************************************************************
**************************************************************************************************************
	Default Screen Settings
**************************************************************************************************************
**************************************************************************************************************
	The program assumes a standard 4:3 screen ratio (e.g. 800x600 pixels, 1024x768 pixels).
	To enforce this on systems with non-standard (e.g. widescreen) resolutions, add something 
	like '/ windowsize = (800px, 600px)' to the 'defaults' element.
**************************************************************************************************************
**************************************************************************************************************
<defaults>
/ minimumversion = "3.0.3.2"
/ fontstyle = ("Verdana", 3.5%, true, false, false, false, 5, 0)
/ inputdevice = mouse
/ screencolor = (black)
/ txcolor = (white)
/ txbgcolor = (transparent)
/ halign = left
/ valign = top
</defaults>

**************************************************************************************************************
**************************************************************************************************************
	Counter Elements
**************************************************************************************************************
**************************************************************************************************************
	Counters 'color1select' and 'color2select' randomly pick a pair of color values at the start of
	each round (e.g. 'red - green'). More colors may be added to these counters or the existing 
	flavors can be modified.
**************************************************************************************************************
**************************************************************************************************************
<counter color1select>
/ items = (yellow, red, magenta, blue, green, cyan)
/ select = replacenorepeat
/ selectionrate = trial
</counter>

<counter color2select>
/ items = (blue, green, cyan, yellow, red, magenta)
/ select = current(color1select)
/ selectionrate = trial
</counter>

**************************************************************************************************************
**************************************************************************************************************
	Counters 'ncolor1select' and 'ncolor2select' determine the proportions of colored squares
	at the start of each round (e.g. 17 red squares and 8 green squares). Currently, the minimum
	number of squares of a given color is set to 7, e.g. there will be *at least* 7 'red' squares in
	any given round. You can change the proportions by removing or adding values in both 
	counters. Note that corresponding values *must* add up to 25 (e.g. 9 + 16 = 25).

	If you wanted to allow the full range of proportions, you would have to define
	'/ items = (0,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25)'
	for counter 'ncolor1select' and
	'/ items = (25,24,23,22,21,20,19,18,17,16,15,14,13,12,11,10,9,8,7,6,5,4,3,2,1,0)'
	for counter 'ncolor2select' respectively.
	
	You can also apply different selection settings to counter 'ncolor1select', such as
	'/ select = replace' or '/ select = replacenorepeat'.
**************************************************************************************************************
**************************************************************************************************************
<counter ncolor1select>
/ items = (7,8,9,10,11,12,13,14,15,16,17,18)
/ select = noreplace
/ selectionrate = trial
</counter>

<counter ncolor2select>
/ items = (18,17,16,15,14,13,12,11,10,9,8,7)
/ select = current(ncolor1select)
/ selectionrate = trial
</counter>

**************************************************************************************************************
**************************************************************************************************************
	!!! YOU PROBABLY DON'T WANT TO CHANGE ANYTHING BELOW THIS SECTION !!!
**************************************************************************************************************
**************************************************************************************************************
	Counter 'assigncolor' is used by trial 'selectcolor' to randomly assign color values to the
	25 squares. Do not make any changes to this counter!
**************************************************************************************************************
**************************************************************************************************************
<counter assigncolor>
/ items = (1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25)
/ select = noreplace
/ selectionrate = always
</counter>

**************************************************************************************************************
**************************************************************************************************************
	Trial Definitions
**************************************************************************************************************
**************************************************************************************************************
	Trial 'selectcolor' is a dummy trial that is run once at the start of each round. 
	It performs the following tasks:
	(1) Pick random values for color 1 and color 2.
	(2) Determine how many squares should be assigned color 1 and color 2 respectively.
	(3) Randomly assign color 1 or color 2 to each of the cells according to (2).
**************************************************************************************************************
**************************************************************************************************************
<trial selectcolor>
/ ontrialbegin = [values.win = values.currentwin; values.responsestorage = ""; values.decision = "";
	values.npicks = 0; values.color1pick = 0; values.color2pick = 0;
	values.roundcount = values.roundcount + 1]
/ ontrialbegin = [values.color1 = counter.color1select.selectedvalue;
	values.color2 = counter.color2select.selectedvalue]
/ ontrialbegin = [values.ncolor1 = counter.ncolor1select.selectedvalue;
	values.ncolor2 = counter.ncolor2select.selectedvalue]
/ ontrialend = [text.color1.textbgcolor = values.color1; text.color2.textbgcolor = values.color2]
/ ontrialend = [if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R1C1.textbgcolor=values.color1 else text.R1C1.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R1C2.textbgcolor=values.color1 else text.R1C2.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R1C3.textbgcolor=values.color1 else text.R1C3.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R1C4.textbgcolor=values.color1 else text.R1C4.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R1C5.textbgcolor=values.color1 else text.R1C5.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R2C1.textbgcolor=values.color1 else text.R2C1.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R2C2.textbgcolor=values.color1 else text.R2C2.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R2C3.textbgcolor=values.color1 else text.R2C3.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R2C4.textbgcolor=values.color1 else text.R2C4.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R2C5.textbgcolor=values.color1 else text.R2C5.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R3C1.textbgcolor=values.color1 else text.R3C1.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R3C2.textbgcolor=values.color1 else text.R3C2.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R3C3.textbgcolor=values.color1 else text.R3C3.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R3C4.textbgcolor=values.color1 else text.R3C4.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R3C5.textbgcolor=values.color1 else text.R3C5.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R4C1.textbgcolor=values.color1 else text.R4C1.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R4C2.textbgcolor=values.color1 else text.R4C2.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R4C3.textbgcolor=values.color1 else text.R4C3.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R4C4.textbgcolor=values.color1 else text.R4C4.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R4C5.textbgcolor=values.color1 else text.R4C5.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R5C1.textbgcolor=values.color1 else text.R5C1.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R5C2.textbgcolor=values.color1 else text.R5C2.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R5C3.textbgcolor=values.color1 else text.R5C3.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R5C4.textbgcolor=values.color1 else text.R5C4.textbgcolor=values.color2;
	if(counter.assigncolor.selectedvalue <= values.ncolor1)
	text.R5C5.textbgcolor=values.color1 else text.R5C5.textbgcolor=values.color2]
/ ontrialend = [
	text.CR1C1.textbgcolor=grey; text.CR1C2.textbgcolor=grey; text.CR1C3.textbgcolor=grey;
	text.CR1C4.textbgcolor=grey; text.CR1C5.textbgcolor=grey; text.CR2C1.textbgcolor=grey;
	text.CR2C2.textbgcolor=grey; text.CR2C3.textbgcolor=grey; text.CR2C4.textbgcolor=grey;
	text.CR2C5.textbgcolor=grey; text.CR3C1.textbgcolor=grey; text.CR3C2.textbgcolor=grey;
	text.CR3C3.textbgcolor=grey; text.CR3C4.textbgcolor=grey; text.CR3C5.textbgcolor=grey;
	text.CR4C1.textbgcolor=grey; text.CR4C2.textbgcolor=grey; text.CR4C3.textbgcolor=grey;
	text.CR4C4.textbgcolor=grey; text.CR4C5.textbgcolor=grey; text.CR5C1.textbgcolor=grey;
	text.CR5C2.textbgcolor=grey; text.CR5C3.textbgcolor=grey; text.CR5C4.textbgcolor=grey;
	text.CR5C5.textbgcolor=grey]
/ validresponse = (noresponse)
/ trialduration = 0
/ branch = [trial.IST]
/ recorddata = false
</trial>

**************************************************************************************************************
**************************************************************************************************************
	Trial 'IST' is the task's main trial, in which subjects click on greyed out boxes to reveal
	their color.
**************************************************************************************************************
**************************************************************************************************************
<trial IST>
/ stimulusframes = [1=matrixbg, color1, color2, win, lose, 
	ncolor1, ncolor2, color1pick, color2pick, roundcount,
	CR1C1, CR1C2, CR1C3, CR1C4, CR1C5, CR2C1, CR2C2, CR2C3, CR2C4, CR2C5,
	CR3C1, CR3C2, CR3C3, CR3C4, CR3C5, CR4C1, CR4C2, CR4C3, CR4C4, CR4C5, 
	CR5C1, CR5C2, CR5C3, CR5C4, CR5C5]
/ isvalidresponse = [contains(values.responsestorage, trial.IST.response) == 0]
/ validresponse = (color1, color2, CR1C1, CR1C2, CR1C3, CR1C4, CR1C5,
	CR2C1, CR2C2, CR2C3, CR2C4, CR2C5,CR3C1, CR3C2, CR3C3, CR3C4, CR3C5, 
	CR4C1, CR4C2, CR4C3, CR4C4, CR4C5, CR5C1, CR5C2, CR5C3, CR5C4, CR5C5)
/ ontrialend = [
	if(trial.IST.response=="CR1C1"){text.CR1C1.textbgcolor=text.R1C1.textbgcolor};
	if(trial.IST.response=="CR1C2"){text.CR1C2.textbgcolor=text.R1C2.textbgcolor};
	if(trial.IST.response=="CR1C3"){text.CR1C3.textbgcolor=text.R1C3.textbgcolor};
	if(trial.IST.response=="CR1C4"){text.CR1C4.textbgcolor=text.R1C4.textbgcolor};
	if(trial.IST.response=="CR1C5"){text.CR1C5.textbgcolor=text.R1C5.textbgcolor};
	if(trial.IST.response=="CR2C1"){text.CR2C1.textbgcolor=text.R2C1.textbgcolor};
	if(trial.IST.response=="CR2C2"){text.CR2C2.textbgcolor=text.R2C2.textbgcolor};
	if(trial.IST.response=="CR2C3"){text.CR2C3.textbgcolor=text.R2C3.textbgcolor};
	if(trial.IST.response=="CR2C4"){text.CR2C4.textbgcolor=text.R2C4.textbgcolor};
	if(trial.IST.response=="CR2C5"){text.CR2C5.textbgcolor=text.R2C5.textbgcolor};
	if(trial.IST.response=="CR3C1"){text.CR3C1.textbgcolor=text.R3C1.textbgcolor};
	if(trial.IST.response=="CR3C2"){text.CR3C2.textbgcolor=text.R3C2.textbgcolor};
	if(trial.IST.response=="CR3C3"){text.CR3C3.textbgcolor=text.R3C3.textbgcolor};
	if(trial.IST.response=="CR3C4"){text.CR3C4.textbgcolor=text.R3C4.textbgcolor};
	if(trial.IST.response=="CR3C5"){text.CR3C5.textbgcolor=text.R3C5.textbgcolor};
	if(trial.IST.response=="CR4C1"){text.CR4C1.textbgcolor=text.R4C1.textbgcolor};
	if(trial.IST.response=="CR4C2"){text.CR4C2.textbgcolor=text.R4C2.textbgcolor};
	if(trial.IST.response=="CR4C3"){text.CR4C3.textbgcolor=text.R4C3.textbgcolor};
	if(trial.IST.response=="CR4C4"){text.CR4C4.textbgcolor=text.R4C4.textbgcolor};
	if(trial.IST.response=="CR4C5"){text.CR4C5.textbgcolor=text.R4C5.textbgcolor};
	if(trial.IST.response=="CR5C1"){text.CR5C1.textbgcolor=text.R5C1.textbgcolor};
	if(trial.IST.response=="CR5C2"){text.CR5C2.textbgcolor=text.R5C2.textbgcolor};
	if(trial.IST.response=="CR5C3"){text.CR5C3.textbgcolor=text.R5C3.textbgcolor};
	if(trial.IST.response=="CR5C4"){text.CR5C4.textbgcolor=text.R5C4.textbgcolor};
	if(trial.IST.response=="CR5C5"){text.CR5C5.textbgcolor=text.R5C5.textbgcolor};]
/ ontrialend = [if(trial.IST.response!="color1" && trial.IST.response!="color2")
	{values.win = values.win - values.decrement; values.npicks = values.npicks + 1}]
/ ontrialend = [
	if(trial.IST.response=="CR1C1" && text.R1C1.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR1C2" && text.R1C2.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR1C3" && text.R1C3.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR1C4" && text.R1C4.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR1C5" && text.R1C5.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR2C1" && text.R2C1.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR2C2" && text.R2C2.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR2C3" && text.R2C3.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR2C4" && text.R2C4.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR2C5" && text.R2C5.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR3C1" && text.R3C1.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR3C2" && text.R3C2.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR3C3" && text.R3C3.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR3C4" && text.R3C4.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR3C5" && text.R3C5.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR4C1" && text.R4C1.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR4C2" && text.R4C2.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR4C3" && text.R4C3.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR4C4" && text.R4C4.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR4C5" && text.R4C5.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR5C1" && text.R5C1.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR5C2" && text.R5C2.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR5C3" && text.R5C3.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR5C4" && text.R5C4.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1;
	if(trial.IST.response=="CR5C5" && text.R5C5.textbgcolor==values.color1)
	values.color1pick = values.color1pick + 1]
/ ontrialend = [values.color2pick = values.npicks - values.color1pick]
/ ontrialend = [values.responsestorage = concat(values.responsestorage, trial.IST.response)]
/ responsemessage = (CR1C1, R1C1, 0) / responsemessage = (CR1C2, R1C2, 0)
/ responsemessage = (CR1C3, R1C3, 0) / responsemessage = (CR1C4, R1C4, 0)
/ responsemessage = (CR1C5, R1C5, 0) / responsemessage = (CR2C1, R2C1, 0)
/ responsemessage = (CR2C2, R2C2, 0) / responsemessage = (CR2C3, R2C3, 0)
/ responsemessage = (CR2C4, R2C4, 0) / responsemessage = (CR2C5, R2C5, 0)
/ responsemessage = (CR3C1, R3C1, 0) / responsemessage = (CR3C2, R3C2, 0)
/ responsemessage = (CR3C3, R3C3, 0) / responsemessage = (CR3C4, R3C4, 0)
/ responsemessage = (CR3C5, R3C5, 0) / responsemessage = (CR4C1, R4C1, 0)
/ responsemessage = (CR4C2, R4C2, 0) / responsemessage = (CR4C3, R4C3, 0)
/ responsemessage = (CR4C4, R4C4, 0) / responsemessage = (CR4C5, R4C5, 0)
/ responsemessage = (CR5C1, R5C1, 0) / responsemessage = (CR5C2, R5C2, 0)
/ responsemessage = (CR5C3, R5C3, 0) / responsemessage = (CR5C4, R5C4, 0)
/ responsemessage = (CR5C5, R5C5, 0)
/ branch = [if(trial.IST.response == "color1" || trial.IST.response == "color2")
	trial.uncover else trial.IST]
</trial>

**************************************************************************************************************
**************************************************************************************************************
	Trial 'uncover' is a utility trial. It reveals the whole grid of colored squares, tallies the results, 
	provides appropriate feedback and implements a variable inter-trial-interval (ITI).
**************************************************************************************************************
**************************************************************************************************************
<trial uncover>
/ ontrialbegin = [if(trial.IST.response == "color1" && values.ncolor1 > values.ncolor2){
	values.feedbackswitch = 1; values.totalpoints = values.totalpoints + values.win;
	values.decision = "correct"}]
/ ontrialbegin = [if(trial.IST.response == "color2" && values.ncolor2 > values.ncolor1){
	values.feedbackswitch = 1; values.totalpoints = values.totalpoints + values.win;
	values.decision = "correct"}]
/ ontrialbegin = [if(trial.IST.response == "color1" && values.ncolor1 < values.ncolor2){
	values.feedbackswitch = 2; values.totalpoints = values.totalpoints - values.lose;
	values.decision = "wrong"}]
/ ontrialbegin = [if(trial.IST.response == "color2" && values.ncolor2 < values.ncolor1){
	values.feedbackswitch = 2; values.totalpoints = values.totalpoints - values.lose;
	values.decision = "wrong"}]
/ ontrialend = [if(values.roundcount >= values.nrounds) values.stopblock = 1]
/ stimulustimes = [0=blankscreen, win, lose, feedback, matrixbg,
	R1C1, R1C2, R1C3, R1C4, R1C5, R2C1, R2C2, R2C3, R2C4, R2C5, 
	R3C1, R3C2, R3C3, R3C4, R3C5, R4C1, R4C2, R4C3, R4C4, R4C5, 
	R5C1, R5C2, R5C3, R5C4, R5C5; 2000=blankscreen, totalpoints]
/ validresponse = (noresponse)
/ showmousecursor = false
/ trialduration = 2000 + round(rand(1000,5000))
/ branch = [trial.selectcolor]
</trial>

**************************************************************************************************************
**************************************************************************************************************
	Text Elements
**************************************************************************************************************
**************************************************************************************************************
<text color1>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (12%, 16%)
/ hposition = 49.25%
/ vposition = 77%
/ hjustify = center
/ vjustify = center
/ halign = right
/ erase = false
</text>

<text color2>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (12%, 16%)
/ hposition = 50.75%
/ vposition = 77%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text ncolor1>
/ items = ("Color 1 = <%values.ncolor1%>")
/ txcolor = (black)
/ txbgcolor = (black)
/ size = (24%, 5%)
/ position = (76%, 30%)
/ hjustify = left
/ valign = center
/ erase = false
</text>

<text ncolor2>
/ items = ("Color 2 = <%values.ncolor2%>")
/ txcolor = (black)
/ txbgcolor = (black)
/ size = (24%, 5%)
/ position = (76%, 35%)
/ hjustify = left
/ valign = center
/ erase = false
</text>

<text color1pick>
/ items = ("Color 1 = <%values.color1pick%>")
/ txcolor = (black)
/ txbgcolor = (black)
/ size = (24%, 5%)
/ position = (76%, 50%)
/ hjustify = left
/ valign = center
/ erase = false
</text>

<text color2pick>
/ items = ("Color 2 = <%values.color2pick%>")
/ txcolor = (black)
/ txbgcolor = (black)
/ size = (24%, 5%)
/ position = (76%, 55%)
/ hjustify = left
/ valign = center
/ erase = false
</text>

<text roundcount>
/ items = ("<%values.roundcount%>/<%values.nrounds%>")
/ txcolor = (black)
/ txbgcolor = (black)
/ size = (20%, 5%)
/ position = (76%, 95%)
/ hjustify = right
/ valign = center
/ erase = false
</text>

<text win>
/ items = ("Win:~t<%values.win%>")
/ txbgcolor = (black)
/ size = (20%, 5%)
/ position = (3%, 22%)
/ hjustify = left
/ valign = center
/ erase = false
</text>

<text lose>
/ items = ("Lose:~t<%values.lose%>")
/ txbgcolor = (black)
/ size = (20%, 5%)
/ position = (3%, 27%)
/ hjustify = left
/ valign = center
/ erase = false
</text>

<text totalpoints>
/ items = ("Total points: <%values.totalpoints%>")
/ halign = center
/ valign = center
</text>

<text feedback>
/ items = ("Correct! You have won <%values.win%> points.", 
	"Wrong! You have lost <%values.lose%> points.")
/ select = values.feedbackswitch
/ position = (50%, 78%)
/ halign = center
/ valign = center
</text>

<shape blankscreen>
/ shape = rectangle
/ color = (black)
/ size = (100%, 100%)
/ position = (50%, 50%)
/ halign = center
/ valign = center
</shape>

**************************************************************************************************************
**************************************************************************************************************
	Screen Layout Elements for the Square Grid
**************************************************************************************************************
**************************************************************************************************************
	All stimuli below this section are positioned *relative* to text 'matrixbg'. If you want to move
	the whole grid around, simply change '/ hposition' and '/ vposition' in text 'matrixbg'.
**************************************************************************************************************
**************************************************************************************************************
<text matrixbg>
/ items = (" ")
/ txbgcolor = (black)
/ size = (48.00%, 64.125%)
/ hposition = 26%
/ vposition = 5%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

**************************************************************************************************************
**************************************************************************************************************
	These elements are used as colored squares. Colors are randomly assigned by trial 'selectcolor'
	during runtime.
**************************************************************************************************************
**************************************************************************************************************
<text R1C1>
/ items = (" ")
/ txbgcolor = (green)
/ size = (9.375%, 12.5%)
/ hposition = text.matrixbg.hposition+0.20%
/ vposition = text.matrixbg.vposition+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R1C2>
/ items = (" ")
/ txbgcolor = (green)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C1.hposition+text.R1C1.width+0.20%
/ vposition = text.matrixbg.vposition+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R1C3>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C2.hposition+text.R1C2.width+0.20% 
/ vposition = text.matrixbg.vposition+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R1C4>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C3.hposition+text.R1C3.width+0.20% 
/ vposition = text.matrixbg.vposition+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R1C5>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C4.hposition+text.R1C4.width+0.20% 
/ vposition = text.matrixbg.vposition+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R2C1>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.matrixbg.hposition+0.20%
/ vposition = text.R1C1.vposition+text.R1C1.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R2C2>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C1.hposition+text.R1C1.width+0.20%
/ vposition = text.R1C2.vposition+text.R1C2.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R2C3>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C2.hposition+text.R1C2.width+0.20% 
/ vposition = text.R1C3.vposition+text.R1C3.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R2C4>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C3.hposition+text.R1C3.width+0.20% 
/ vposition = text.R1C4.vposition+text.R1C4.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R2C5>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C4.hposition+text.R1C4.width+0.20% 
/ vposition = text.R1C5.vposition+text.R1C5.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R3C1>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.matrixbg.hposition+0.20%
/ vposition = text.R2C1.vposition+text.R2C1.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R3C2>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C1.hposition+text.R1C1.width+0.20%
/ vposition = text.R2C2.vposition+text.R2C2.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R3C3>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C2.hposition+text.R1C2.width+0.20% 
/ vposition = text.R2C3.vposition+text.R2C3.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R3C4>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C3.hposition+text.R1C3.width+0.20% 
/ vposition = text.R2C4.vposition+text.R2C4.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R3C5>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C4.hposition+text.R1C4.width+0.20% 
/ vposition = text.R2C5.vposition+text.R2C5.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R4C1>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.matrixbg.hposition+0.20%
/ vposition = text.R3C1.vposition+text.R3C1.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R4C2>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C1.hposition+text.R1C1.width+0.20%
/ vposition = text.R3C2.vposition+text.R3C2.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R4C3>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C2.hposition+text.R1C2.width+0.20% 
/ vposition = text.R3C3.vposition+text.R3C3.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R4C4>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C3.hposition+text.R1C3.width+0.20% 
/ vposition = text.R3C4.vposition+text.R3C4.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R4C5>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C4.hposition+text.R1C4.width+0.20% 
/ vposition = text.R3C5.vposition+text.R3C5.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R5C1>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.matrixbg.hposition+0.20%
/ vposition = text.R4C1.vposition+text.R4C1.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R5C2>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C1.hposition+text.R1C1.width+0.20%
/ vposition = text.R4C2.vposition+text.R4C2.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R5C3>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C2.hposition+text.R1C2.width+0.20% 
/ vposition = text.R4C3.vposition+text.R4C3.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R5C4>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C3.hposition+text.R1C3.width+0.20% 
/ vposition = text.R4C4.vposition+text.R4C4.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text R5C5>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C4.hposition+text.R1C4.width+0.20% 
/ vposition = text.R4C5.vposition+text.R4C5.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

**************************************************************************************************************
**************************************************************************************************************
	These elements are used to cover the colored squares.
**************************************************************************************************************
**************************************************************************************************************
<text CR1C1>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.matrixbg.hposition+0.20%
/ vposition = text.matrixbg.vposition+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR1C2>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C1.hposition+text.R1C1.width+0.20%
/ vposition = text.matrixbg.vposition+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR1C3>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C2.hposition+text.R1C2.width+0.20% 
/ vposition = text.matrixbg.vposition+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR1C4>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C3.hposition+text.R1C3.width+0.20% 
/ vposition = text.matrixbg.vposition+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR1C5>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C4.hposition+text.R1C4.width+0.20% 
/ vposition = text.matrixbg.vposition+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR2C1>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.matrixbg.hposition+0.20%
/ vposition = text.R1C1.vposition+text.R1C1.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR2C2>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C1.hposition+text.R1C1.width+0.20%
/ vposition = text.R1C2.vposition+text.R1C2.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR2C3>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C2.hposition+text.R1C2.width+0.20% 
/ vposition = text.R1C3.vposition+text.R1C3.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR2C4>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C3.hposition+text.R1C3.width+0.20% 
/ vposition = text.R1C4.vposition+text.R1C4.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR2C5>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C4.hposition+text.R1C4.width+0.20% 
/ vposition = text.R1C5.vposition+text.R1C5.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR3C1>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.matrixbg.hposition+0.20%
/ vposition = text.R2C1.vposition+text.R2C1.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR3C2>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C1.hposition+text.R1C1.width+0.20%
/ vposition = text.R2C2.vposition+text.R2C2.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR3C3>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C2.hposition+text.R1C2.width+0.20% 
/ vposition = text.R2C3.vposition+text.R2C3.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR3C4>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C3.hposition+text.R1C3.width+0.20% 
/ vposition = text.R2C4.vposition+text.R2C4.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR3C5>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C4.hposition+text.R1C4.width+0.20% 
/ vposition = text.R2C5.vposition+text.R2C5.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR4C1>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.matrixbg.hposition+0.20%
/ vposition = text.R3C1.vposition+text.R3C1.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR4C2>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C1.hposition+text.R1C1.width+0.20%
/ vposition = text.R3C2.vposition+text.R3C2.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR4C3>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C2.hposition+text.R1C2.width+0.20% 
/ vposition = text.R3C3.vposition+text.R3C3.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR4C4>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C3.hposition+text.R1C3.width+0.20% 
/ vposition = text.R3C4.vposition+text.R3C4.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR4C5>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C4.hposition+text.R1C4.width+0.20% 
/ vposition = text.R3C5.vposition+text.R3C5.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR5C1>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.matrixbg.hposition+0.20%
/ vposition = text.R4C1.vposition+text.R4C1.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR5C2>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C1.hposition+text.R1C1.width+0.20%
/ vposition = text.R4C2.vposition+text.R4C2.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR5C3>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C2.hposition+text.R1C2.width+0.20% 
/ vposition = text.R4C3.vposition+text.R4C3.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR5C4>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C3.hposition+text.R1C3.width+0.20% 
/ vposition = text.R4C4.vposition+text.R4C4.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

<text CR5C5>
/ items = (" ")
/ txbgcolor = (grey)
/ size = (9.375%, 12.5%)
/ hposition = text.R1C4.hposition+text.R1C4.width+0.20% 
/ vposition = text.R4C5.vposition+text.R4C5.height+0.26%
/ hjustify = center
/ vjustify = center
/ erase = false
</text>

**************************************************************************************************************
**************************************************************************************************************
	End Of File
**************************************************************************************************************
**************************************************************************************************************