Millisecond Forums

(1) Your use of the /iscorrectresponse attribute is incorrect. You need an expression that evaluates to either true or false, i.e. something along the lines of

<trial target>
...
/ iscorrectresponse = [trial.target.response == list.correctresp.nextvalue]
...
</trial>

(2) A trial's response property returns a given key's *numerical keyboard scancode* (cf. the "Keyboard Scan Codes" topic in the documentation and Tools -> Keyboard Scancodes...), not a key's "literal" value (e.g. the letter imprinted on it). Your <list> element ought to reflect that:

*36 = scancode for the "j"-key / 33 = scancode for the "f"-key*
<list correctresp>
/ items = (36,36,36,36,36,
33,33,33,33,33)
/ selectionmode = list.targettype.currentindex
</list>

Here's a barebones, minimal (but runnable & self-contained) example:
<block myblock>
/ trials = [1-4 = mytrial]
</block>

<trial mytrial>
/ stimulusframes = [1=mytext]
/ validresponse = ("a", "b")
/ iscorrectresponse = [trial.mytrial.response == list.cresp.nextvalue]
/ errormessage = true(errormsg, 500)
/ correctmessage = true(correctmsg, 500)
</trial>

<text mytext>
/ items = ("A1", "A2", "B1", "B2")
</text>

* 30 = scancode for "A"-key / 48 = scancode for "B"-key *
<list cresp>
/ items = (30, 30, 48, 48)
/ selectionmode = text.mytext.currentindex
</list>

<text errormsg>
/ items = ("ERROR")
/ position = (50%, 75%)
</text>

<text correctmsg>
/ items = ("CORRECT")
/ position = (50%, 75%)
</text>

Dave,

Thank you for your response. I corrected the keycode scan codes and tried your suggestion with the error message and discovered that the program is considering every response as an error.  So the trouble is that somehow I have not programmed the correct stimuli with the correct response.  Perhaps the trouble is here?:

<picture target>
/ items = (1 = "VGO.bmp", 2 = "VNOGO.bmp")
/ size = (75mm,75mm)
/ position = (50%,50%)
/ erase = false
</picture>

the only place I have designated what the correct response is in the following:

<list targettype>
/ items = (
1,1,1,1,1,
2,2,2,2,2)
/ selectionmode = random
</list>

<list correctresp>
/ items = (36,36,36,36,36,
33,33,33,33,33)
/ selectionmode = list.targettype.currentindex
</list>

Will this script tell the program to select target 1 or 2 randomly and choose the corresponding correct response from the list?  I am pretty sure I am missing a critical item.  

Thank you!

You have not defined any relationship between your <picture> element and the respective <list>s.

Nothing in the code excerpts you posted suggests that <list targettype> would ever be sampled from. If you go back to the example in my previous reply, notice the dependency between the stimulus (<text>) element and the <list> holding the correct responses.

In your case, do

<picture target>
/ items = ("VGO.bmp", "VNOGO.bmp")
/ size = (75mm,75mm)
/ position = (50%,50%)
/ erase = false
/ select = list.targettype.nextvalue
</picture>

That was what I was missing!  Thanks so much!!!