Millisecond Forums

Your description is too vague. You need to elaborate. You also need to spell out *clearly* which is which.

> There are eight versions of the same stimuli divided into two groups: four versions with "YES" as correct response and the other four with "NO" as correct response.

For *which* stimuli is "yes" the correct response. For *which* is it no.

Sorry, I'll try to describe it better.

In the previous message, I put three stimuli in the sample lists. Each stimuli have the eight corresponding versions divided into two groups (targetA and targetB). The correct response for each stimuli is the same as the "targetlabel". I.e, the versions 1_1, 1_2, 1_3 and 1_4 of the stimulus 1 correspond to the targetA group and with "YES" as correct response, and the versions 1_5, 1_6, 1_7 and 1_8 of that stimulus with "NO" as correct response. The same for the rest of stimuli.

If the explanation is no clear, please let me know and I'll try to explain it in a different way.

Thank you,

Naiara

Sorry, it's still not clear to me. Stimuli being "same" or "different" implies a comparison between *two* stimuli. What is being compared here? I.e., version 1_1 is "same" respective to what? 1_2 is "same" respective to what? Similarly, 1_5 is "different" respective to what?

It's also not clear to me what "corresponding versions" means to begin with. Please give a concrete example. Describe *precisely* how you imagine a "same" trial to look. Do the same for a "different" trial. Describe what distinguishes the different "corresponding versions" of the stimuli and how those relate to the randomization constraints. Thanks.

I understand your doubts. I described badly what it means to "compare stimuli" in the task. I do not need to compare the stimuli, since the image corresponding, for example, to stimulus 1_1 is composed of two "sub" images. I think that it is better to explain it with an example:

Stimulus 1 corresponds with flower pictures. Thus, the different versions of this stimulus correspond with diferents colour of these flowers. I.e,

Stimulus Version        Image                                         Correct response (are the same?)
1_1                         Red flower vs Red flower                   YES
1_2                         Green flower vs Green flower             YES
1_3                         Blue flower vs Blue flower                  YES
1_4                         Yellow flower vs Yellow flower            YES

1_1                       Red flower vs Green flower                   NO
1_2                       Green flower vs Red flower                   NO
1_3                       Blue flower vs Yellow flower                 NO
1_4                       Yellow flower vs Blue flower                 NO

The stimulus 2 corresponds with dog pictures, the stimulus 3 corresponds with apple pictures...

So, the correct response make reference to the response which participants should give in the test to each stimuli version.

Okay, thanks. That clarifies somewhat. On that basis:
"1. No more than two consecutive versions of the same stimuli may appear."
I assume you consider all stimuli belonging to the same "group" (e.g. any images involving flowers, regardless of their respective colors, and regardless of whether the colors are identical or not) to be "same". Please confirm or -- if incorrect -- clarify.

I also don't understand how stimulus 1_1 can simultaneously be composed of two red flowers
1_1                         Red flower vs Red flower                   YES
...
and one red and one green flower
1_1                       Red flower vs Green flower                   NO
...
(same for 1_2, 1_3, ...)

I assume this is a mistake or is there anything else I'm not catching? Thanks.

Under the assumption that my understanding is correct (or at least close to correct), you need to do the following:

- You need two <trial> elements -- one for "same" (answer: yes), another one for "different" (answer: no).
- To implement the 2nd constraint
"2. No more than three stimuli with the same correct response (YES or NO) may appear."
you need to use a <list> for trial-selection. Its /maxrunsize ought to be set to 3.

<list trial_selector>
/ items = (trial.same_trial, trial.diff_trial)
/ poolsize = 24
/ maxrunsize = 3
</list>

<block same_diff_block>
/ trials = [1-24 = list.trial_selector]
</block>

- To implement the 1st constraint
"1. No more than two consecutive versions of the same stimuli may appear."
you need <list>s that encode which "category" (e.g. flowers, apples) each stimulus belongs to. You use those lists for stimulus-selection.
Additionally, you need to keep track of the categories at runtime, also via a <list> that's updated by the <trial> elements /ontrialend. If the last two items administered belong to the same category, you block that category for selection in the next trial via a /not constraint.

The end result would be something like this:

<values>
/ blocked_cat = 0
</values>

// no more than 3 trials of the same type in a row
<list trial_selector>
/ items = (trial.same_trial, trial.diff_trial)
/ poolsize = 24
/ maxrunsize = 3
</list>

<block same_diff_block>
/ trials = [1-24 = list.trial_selector]
</block>

<trial same_trial>
/ ontrialend = [list.cat_tracker.insertitem(list.cat_list_same.currentvalue, 1) ;]
/ ontrialend = [if (list.cat_tracker.item(1) == list.cat_tracker.item(2)) values.blocked_cat = list.cat_tracker.item(1)
    else values.blocked_cat = 0; ]
/ stimulusframes = [1=same_stim, question, yes, no]
/ inputdevice = mouse
/ validresponse = (yes, no)
/ correctresponse = (yes)
</trial>

<trial diff_trial>
/ ontrialend = [list.cat_tracker.insertitem(list.cat_list_diff.currentvalue, 1) ;]
/ ontrialend = [if (list.cat_tracker.item(1) == list.cat_tracker.item(2)) values.blocked_cat = list.cat_tracker.item(1)
    else values.blocked_cat = 0; ]
/ stimulusframes = [1=diff_stim, question, yes, no]
/ inputdevice = mouse
/ validresponse = (yes, no)
/ correctresponse = (no)
</trial>

// track the categories administered at runtime
<list cat_tracker>
/ items = (0)
</list>

<text same_stim>
/ items = same_items
/ select = list.cat_list_same.nextindex
</text>

// items 1 to 4 in same_stim belong to category 1
// items 5 to 8 in same_stim belong to category 2
// items 9 to 12 in same_stim belong to category 3
<list cat_list_same>
/ items = (1,1,1,1,
    2,2,2,2,
    3,3,3,3)
/ not = (values.blocked_cat)
</list>

<item same_items>
/1 = "1_1 (same)"
/2 = "1_2 (same)"
/3 = "1_3 (same)"
/4 = "1_4 (same)"

/5 = "2_1 (same)"
/6 = "2_2 (same)"
/7 = "2_3 (same)"
/8 = "2_4 (same)"

/9 = "3_1 (same)"
/10 = "3_2 (same)"
/11 = "3_3 (same)"
/12 = "3_4 (same)"
</item>

<text diff_stim>
/ items = diff_items
/ select = list.cat_list_diff.nextindex
</text>

// items 1 to 4 in diff_stim belong to category 1
// items 5 to 8 in diff_stim belong to category 2
// items 9 to 12 in diff_stim belong to category 3
<list cat_list_diff>
/ items = (1,1,1,1,
    2,2,2,2,
    3,3,3,3)
/ not = (values.blocked_cat)
</list>

<item diff_items>
/1 = "1_5 (diff)"
/2 = "1_6 (diff)"
/3 = "1_7 (diff)"
/4 = "1_8 (diff)"

/5 = "2_5 (diff)"
/6 = "2_6 (diff)"
/7 = "2_7 (diff)"
/8 = "2_8 (diff)"

/9 = "3_5 (diff)"
/10 = "3_6 (diff)"
/11 = "3_7 (diff)"
/12 = "3_8 (diff)"
</item>

<text question>
/ items = ("Are the stimuli identical?")
/ position = (50%, 10%)
</text>

<text yes>
/ items = ("YES")
/ position = (40%, 90%)
</text>

<text no>
/ items = ("NO")
/ position = (60%, 90%)
</text>

Sorry for the delay in response, I have not had access to my account until today.

Thank you very much for the information, it is exactly what I need.

Regards