Millisecond Forums

This should be pretty straightforward to do, the basic setup goes like this:

<text sentence>
/ items = sentence_items
</text>

<item sentence_items>
/ 1 = "Sentence 1"
/ 2 = "Sentence 2"
/ 3 = "Sentence 3"
/ 4 = "Sentence 4"
</item>

<text context_a>
/ items = context_a_items
/ position = (50%, 25%)
/ select = text.sentence.currentindex
</text>

<item context_a_items>
/ 1 = "Sentence 1, Context A"
/ 2 = "Sentence 2, Context A"
/ 3 = "Sentence 3, Context A"
/ 4 = "Sentence 4, Context A"
</item>

<text context_b>
/ items = context_b_items
/ position = (50%, 25%)
/ select = text.sentence.currentindex
</text>

<item context_b_items>
/ 1 = "Sentence 1, Context B"
/ 2 = "Sentence 2, Context B"
/ 3 = "Sentence 3, Context B"
/ 4 = "Sentence 4, Context B"
</item>

<likert ca>
/ stimulusframes = [1=sentence, context_a]
/ anchors = [1="unnatural", 7="natural"]
/ numpoints = 7
/ anchorwidth = 4%
/ position = (50%, 75%)
</likert>

<likert cb>
/ stimulusframes = [1=sentence, context_b]
/ anchors = [1="unnatural", 7="natural"]
/ numpoints = 7
/ anchorwidth = 4%
/ position = (50%, 75%)
</likert>

<block ratingblock>
/ trials = [1-4 = noreplace(ca,cb)]
</block>

Thanks, very much appreciated!

Since I am a newbie, could you elaborate in a few sentences what exactly the trials block does, and how it ensures that every item is seen by every participant, although with a random context?

Thanks again!

The sentence <text> elements samples from its (here: 4) items without replacement. That ensures each sentence is sample exactly once across the 4 trials in the example.

<text sentence>
/ items = sentence_items
</text>

The context A and context B stimuli

<text context_a>
/ items = context_a_items
/ position = (50%, 25%)
/ select = text.sentence.currentindex
</text>

<text context_b>
/ items = context_b_items
/ position = (50%, 25%)
/ select = text.sentence.currentindex
</text>

are set to select the item *corresponding* to the item selected by the sentence <text> element. I.e. they are paired to it, cf. https://www.millisecond.com/support/docs/v5/html/howto/howtopairs.htm

The block runs exactly two "context A" (ca) and two "context B" (cb) trials, i.e. four trials total, sampling ca and cb in equal proportions.

<block ratingblock>
/ trials = [1-4 = noreplace(ca,cb)]
</block>

With your four sentences sampled without replacement, you get two sentences presented with context A, and the other two presented with context B.

/ trials = [1-4 = noreplace(ca,cb)]" part.

Thanks!

Sorry for the double post, my last post only displays the code snippet. So:

Thanks for the response, it makes perfect sense. I have just one more question: I also have filler items in addition to the actual targets. I would like to display my stimuli in such a way that no participant sees two targets or two fillers in succession, so the stimuli are sort of interlaced. I guess I have to do a separare item block for fillers, and pair the contexts the same way, but I'm not sure how to code the ordering of fillers and targets into the "noreplace(ca, cb)" part.

Thanks for your help!

I think it's easiest if you simply leave

<block ratingblock>
/ trials = [1-4 = noreplace(ca,cb)]
</block>

as is, and instead /branch to a filler-trial after each target trial, i.e.

<likert filler>
/ stimulusframes = [1=fillersentence, fillercontext]
/ anchors = [1="unnatural", 7="natural"]
/ numpoints = 7
/ anchorwidth = 4%
/ position = (50%, 75%)
</likert>

with

<likert ca>
/ stimulusframes = [1=sentence, context_a]
/ anchors = [1="unnatural", 7="natural"]
/ numpoints = 7
/ anchorwidth = 4%
/ position = (50%, 75%)
/ branch = [likert.filler]
</likert>

<likert cb>
/ stimulusframes = [1=sentence, context_b]
/ anchors = [1="unnatural", 7="natural"]
/ numpoints = 7
/ anchorwidth = 4%
/ position = (50%, 75%)
/ branch = [likert.filler]
</likert>

That way, you'll get a filler after each target trial, be it ca or cb,

Thanks again! So the "branch = [likert.filler] part unconditionally executes the filler trial block every time one of the target trial blocks are run? It seems easy enough to implement, I'll try this and report back.

Oh, just one more thing: Does this branching structure also ensure that the filler sentences are also paired with their respective context 1-s and context 2-s randomly?

The /branch runs a filler trial after each target (ca or cb) trial -- it's not a block. This has nothing to do with any pairing of filler items. If you need such pairing, you need to set that up in the same way the context A and context B pairings are set up.