Millisecond Forums

Continuous video through survey questions?

https://www.millisecond.com/forums/Topic18320.aspx

By westr2 - 2/11/2016

Hello!
I'm looking for a way to have a video playing continuously while participants answer two consecutive survey questions (a textbox and checkbox). It seems that getting these two questions to appear separately requires two survey pages, and thus a new call to the video. Is this correct, or is there a way to have the video going continuously? Any help would be appreciated!

By Dave - 2/12/2016

If you run your two <surveypage>s as trials in a <block>, you should be able to use the <block>'s /bgstim attribute to have the video playing in the background without interruption.

<block myblock>
/ bgstim = (myvideo)
/ trials = [1=a; 2=b]
</block>

<video myvideo>
/ items = ("video.mp4")
</video>

<surveypage a>
/ questions = [1=mytextbox]
/ showpagenumbers = false
/ showquestionnumbers = false
</surveypage>

<surveypage b>
/ questions = [1=mycheckboxes]
/ showpagenumbers = false
/ showquestionnumbers = false
</surveypage>

<textbox mytextbox>
/ textboxsize = (20%, 5%)
/ position = (40%, 80%)
</textbox>

<checkboxes mycheckboxes>
/ options = ("A", "B", "C")
/ size = (20%, 5%)
/ position = (40%, 80%)
/ orientation = horizontal
</checkboxes>
By westr2 - 2/12/2016

It's working. Thank you so much for your help!