By murich - 12/11/2018
Hello,
Is there a way to make Inquisit record a response, via keyboard, and display that to the participant? We're running an IAT and we'd like to provide a "training" section to help encourage fast responses, but it seems like Inquisit just stores the response time in memory and then outputs it to a file after the experiment is complete. Is it possible to get the time and show it on the screen during the experiment?
|
By Dave - 12/11/2018
+xHello, Is there a way to make Inquisit record a response, via keyboard, and display that to the participant? We're running an IAT and we'd like to provide a "training" section to help encourage fast responses, but it seems like Inquisit just stores the response time in memory and then outputs it to a file after the experiment is complete. Is it possible to get the time and show it on the screen during the experiment?
Yes, of course that's possible. You can access the the response time for a given instance of a <trial> via that trial's latency property. I.e.
<values>
/ RT = ""
</values>
<block example>
/ postinstructions = (end)
/ trials = [1-10 = noreplace(a,b)]
</block>
<trial a>
/ ontrialend = [
values.RT = trial.a.latency;
]
/ stimulusframes = [1=a_stimulus]
/ validresponse = ("a", "b")
/ correctresponse = ("a")
/ branch = [
trial.feedback;
]
</trial>
<trial b>
/ ontrialend = [
values.RT = trial.b.latency;
]
/ stimulusframes = [1=b_stimulus]
/ validresponse = ("a", "b")
/ correctresponse = ("b")
/ branch = [
trial.feedback;
]
</trial>
<trial feedback>
/ stimulusframes = [1=feedback_stimulus]
/ validresponse = (0)
/ trialduration = 4000
</trial>
<text a_stimulus>
/ items = ("Press A")
</text>
<text b_stimulus>
/ items = ("Press B")
</text>
<text feedback_stimulus>
/ items = ("Your response time was <%values.RT%> milliseconds.")
</text>
<page end>
^Your average response time for A-trials was <%trial.a.meanlatency%> milliseconds.
^^Your average response time for B-trials was <%trial.b.meanlatency%> milliseconds.
^^Your overall average response time was <%meanlatency(trial.a, trial.b)%> milliseconds.
</page>
|
By murich - 12/11/2018
+x[quote]+x[quote]Thank you, this is perfect!
|
|