Millisecond Forums

Basic Image Selection/Presentation Task?

https://forums.millisecond.com/Topic27604.aspx

By WestSJ - 8/14/2019

Hello all,
I am relatively new to Inquisit and am trying to create a very basic task but am not quite sure how to get started and none of the sample tasks online are similar.

Essentially my participants need to be able to click (or select with the keyboard, either one) from a list of 6 categories (in this case, emotions) and then see an image from that category (e.g., they pick 'Happiness' and see a picture of some happy babies or something).

I need the categories to be able to display the images at random - but only do repeats after each image in that respective category has been displayed once.

If I could get just some kind of basic guidance on how to set this up I'm sure I could figure it out! Basically I just need someone to show me how to set up a task that lets them choose a category, see an image, then repeat. Thats it!

Many thanks!
By Dave - 8/14/2019

WestSJ - 8/14/2019
Hello all,
I am relatively new to Inquisit and am trying to create a very basic task but am not quite sure how to get started and none of the sample tasks online are similar.

Essentially my participants need to be able to click (or select with the keyboard, either one) from a list of 6 categories (in this case, emotions) and then see an image from that category (e.g., they pick 'Happiness' and see a picture of some happy babies or something).

I need the categories to be able to display the images at random - but only do repeats after each image in that respective category has been displayed once.

If I could get just some kind of basic guidance on how to set this up I'm sure I could figure it out! Basically I just need someone to show me how to set up a task that lets them choose a category, see an image, then repeat. Thats it!

Many thanks!

This should be fairly straightforward to do with basic conditional /branching. Here's an example with two categories -- happy and sad -- with 4 items each:

<block myblock>
/ trials = [1-8 = selectcategory]
</block>

<trial selectcategory>
/ stimulusframes = [1=selectcategory, happy, sad]
/ inputdevice = mouse
/ validresponse = (happy, sad)
/ branch = [
if (trial.selectcategory.response == "happy") {
trial.happytrial;
} else if (trial.selectcategory.response == "sad") {
trial.sadtrial;
}
]
</trial>

<text selectcategory>
/ items = ("Click on a category below:")
/ position = (50%, 10%)
</text>

<text happy>
/ items = ("HAPPY")
/ position = (40%, 50%)
/ size = (15%, 10%)
/ txbgcolor = lightgrey
/ vjustify = center
</text>

<text sad>
/ items = ("SAD")
/ position = (60%, 50%)
/ size = (15%, 10%)
/ txbgcolor = lightgrey
/ vjustify = center
</text>

// displays a happy stimulus for 2.5 seconds
<trial happytrial>
/ stimulusframes = [1=happystimulus]
/ validresponse = (0)
/ trialduration = 2500
</trial>

// displays a sad stimulus for 2.5 seconds
<trial sadtrial>
/ stimulusframes = [1=sadstimulus]
/ validresponse = (0)
/ trialduration = 2500
</trial>

//samples happy items randomly without replacement
<text happystimulus>
/ items = happyitems
/ select = noreplace
</text>

<item happyitems>
/ 1 = "happy_a.jpg"
/ 2 = "happy_b.jpg"
/ 3 = "happy_c.jpg"
/ 4 = "happy_d.jpg"
</item>

//samples sad items randomly without replacement
<text sadstimulus>
/ items = saditems
/ select = noreplace
</text>

<item saditems>
/ 1 = "sad_a.jpg"
/ 2 = "sad_b.jpg"
/ 3 = "sad_c.jpg"
/ 4 = "sad_d.jpg"
</item>