N Back Task

Dave - 10/5/2021

+x

AnthonyFCollinsSussex - 10/5/2021
Hi
I hope all is going well?

I had a very small query regarding Inquisit's N-Back Task. The script attached is derived from the library's own, with only minor changes (mainly instructional slide format).

I would like to simply remove the practice block so participants dive straight in. Thus, in the script attached, I have taken out the practice block in the <expt>. However, when indeed the main task ('s_ntask') begins, there appears 'this is your target' (with a letter) cue, even though this should only appear for zero-n back blocks - yet it is always there at the very start (even for 1 back, 2 back, 3 back when it should not be). Having said that, it only happens at the very start - further into task it does not appear again at the beginning of subsequent blocks. I have really tried to tease out how to eliminate this, and I know it is probably some very minor alteration, but I cannot find out how unfortunately. I was wondering whether there could be something you may spot more easily than myself to prevent this from showing.

I attach a compressed file with the N-back + instructional jpg slides.

Many Thanks in advance
Yours Sincerely
Anthony

The difference is simply that you changed the text color of <text targetreminder> from black in the original

<text targetreminder>
/ items = ("this is the target")
/ position = (50%, 25%)
/ txbgcolor = black
/ txcolor = black
/ fontstyle = ("Arial", 3.00%, false, false, false, false, 5, 0)
</text>

to white in your modification:

<text targetreminder>
/ items = ("this is the target")
/ position = (50%, 25%)
/ txbgcolor = black
/ txcolor = white
/ fontstyle = ("Arial", 3.00%, false, false, false, false, 5, 0)
</text>

i.e. it will be visible against the black background at the start. It's only later set to black, after the 1st start trial.

<trial start>
/ ontrialbegin = [
    if (values.N == 0) {
        text.targetreminder.textcolor = red;
        values.trialduration_starttrial = parameters.showtarget0;
        values.starttrialposttrialpause = parameters.posttrialpause_aftertarget0;
    } else {
        trial.start.insertstimulustime(clearscreen, parameters.stimulusPresentationtime);
        values.trialduration_starttrial = parameters.trialduration;
        values.starttrialposttrialpause = 0;
    };

    values.starttrialcounter += 1;
    values.trial_Hit = 0;
    values.trial_Miss = 0;
    values.trial_CR = 0;
    values.trial_FA = 0;
]
/ stimulustimes = [0 = startletter, targetreminder]
/ validresponse = (noresponse, 21)
/ correctresponse = (noresponse)
/ ontrialend = [
    trial.start.resetstimulusframes();
    if (values.N == 0) {
        values.currenttarget = text.startletter.currentitemnumber;
    }
    list.items.insertitem(text.startletter.currentitemnumber, 1);
    text.targetreminder.textcolor = black;
]
/ beginresponsetime = 0
/trialduration = values.trialduration_starttrial
/posttrialpause = (values.starttrialposttrialpause)
/branch = [if (values.starttrialcounter < values.N) trial.start]
</trial>

Set the txcolor back to black.