|
Group: Forum Members
Posts: 5,
Visits: 26
|
Hey guys,
I'm new to Inquisit. I've almost finished scripting my experiment, but I'm having an issue with the counter. I keep getting this error message:
Element: counter.Negative Attribute: allowrepeats Message: Can not be set to 'true' when selection mode is 'current'.
The only problem is, allowrepeats is set to false. I am getting the same error with my Benign counter as well.
I need to have the experiment run so that sentences are paired with particular negative, benign and unmatched words, and that those pairs are not repeated (so each sentence will be presented three times -once with each word- but will not appear consecutively or too close together). Participants have to respond to both the sentence and the word so I have used separate trials for them. It all works fine without the counter except that pairs get repeated.
This is what I have at the moment (well, some of the relevant bits so you can see what I'm doing):
<text Sentences>
/ items = ("A coworker begins saying the same phrases you do", "A friend does not respond when you wave hello", "Colleagues find your views unusual", "In your interveiw the people do not smile", "People laugh after something you said", "You notice someone pointing in your direction", "Your classmates are surprised by your project", "Your date has to leave early", "Your friend does not call you back", "Your friend opens your present and makes a face", "Your friends think of you differently after a long road trip", "Everyone stops talking when you enter the room", "You and your classmate accidentally bump into each other", "You hear a friend make a joke about you", "You hear your name mentioned in a nearby conversation", "Your boss wants to meet with you", "People always tell you to smile", "You make a first impression on your coworker")
/ select = Sentences
/ color = (255, 255, 255)
/ txbgcolor = (0, 0, 0)
</text>
<text Negative>
/ items = ("Mocked", "Rejected", "Weird", "Failure", "Humiliated", "Ridiculed", "Stupid", "Rejected", "Angry", "Disappointed", "Boring", "Isolated", "Embarrassing", "Insulted", "Ridiculed", "Criticize", "Defective", "Stupid")
/ select = Negative
/ color = (255, 255, 255)
/ txbgcolor = (0,0,0)
</text>
<counter Sentences>
/ allowrepeats = false
/ select = noreplacenorepeat
/ resetinterval = 0
</counter>
<counter Negative>
/ allowrepeats = false
/ select = current(Sentences)
/ resetinterval = 60
</counter>
<trial Sentences>
/ stimulustimes = [0=Fixation; 500=Sentences]
/ validresponse = (" ")
</trial>
<trial Negative>
/stimulustimes = [0=Negative]
/validresponse = ("s", "k")
</trial>
<block SentenceNegative>
/ trials = [1=Sentences;2=Negative]
/ screencolor = (0, 0, 0)
</block>
Hope that all makes sense!!
|
|
Group: Forum Members
Posts: 5,
Visits: 26
|
oh! I also forgot to mention that if I do change it to / allowrepeats = true then the error messages go away??
|
|
Group: Administrators
Posts: 12K,
Visits: 98K
|
<counter Sentences>
/ allowrepeats = false
/ select = noreplacenorepeat
/ resetinterval = 0
</counter>
<counter Negative>
/ allowrepeats = false
/ select = current(Sentences)
/ resetinterval = 60
</counter>
Selection mode current means the item counter.negative selects *depends* on the item selected in counter.sentence. I.e., if the 2nd item in counter.sentence is selected (randomly without replacement / without repetition), counter.negative will select the corresponding item (the 2nd one in counter.negative). You cannot impose any additional selection constraints in counter.negative. Delete the /allowrepeats attribute.
|
|
Group: Forum Members
Posts: 5,
Visits: 26
|
But I can't have the Negative words repeating? Those sentences have to go once with each type of word (Negative, Benign and Unmatched). The 2nd sentence goes with the 2nd Negative word, as well as with the 2nd Benign word and the 2nd Unmatched word. I don't want it to show any pair twice.
|
|
Group: Administrators
Posts: 12K,
Visits: 98K
|
You need to set this up differently. Suppose you have 4 sentences and 3 word categories (1=positive; 2=negative; 3=neutral):
<values>
/ mysentence = 1
/ mywordclass = 1
</values>
<block myblock>
/ trials = [1-12=mytrial]
</block>
<trial mytrial>
/ ontrialbegin = [values.mysentence=counter.sentences.selectedvalue;
values.mywordclass=counter.wordclass.selectedvalue;]
/ ontrialbegin = [if (values.mywordclass==1) text.adjective.item.1 = getitem(item.positive, values.mysentence); ]
/ ontrialbegin = [if (values.mywordclass==2) text.adjective.item.1 = getitem(item.negative, values.mysentence); ]
/ ontrialbegin = [if (values.mywordclass==3) text.adjective.item.1 = getitem(item.neutral, values.mysentence); ]
/ stimulusframes = [1=sentence, adjective]
/ validresponse = (57)
</trial>
<counter sentences>
/ items = (1,1,1,2,2,2,3,3,3,4,4,4)
/ select = noreplacenorepeat
</counter>
<counter wordclass>
/ items = (1,2,3,1,2,3,1,2,3,1,2,3)
/ select = current(sentences)
</counter>
<text sentence>
/ items = sentenceitems
/ select = values.mysentence
</text>
<text adjective>
/ items = ("")
/ position = (50%,60%)
</text>
<item sentenceitems>
/ 1 = "Sentence A"
/ 2 = "Sentence B"
/ 3 = "Sentence C"
/ 4 = "Sentence D"
</item>
<item positive>
/ 1 = "Positive A"
/ 2 = "Positive B"
/ 3 = "Positive C"
/ 4 = "Positive D"
</item>
<item negative>
/ 1 = "Negative A"
/ 2 = "Negative B"
/ 3 = "Negative C"
/ 4 = "Negative D"
</item>
<item neutral>
/ 1 = "Neutral A"
/ 2 = "Neutral B"
/ 3 = "Neutral C"
/ 4 = "Neutral D"
</item>
|
|
Group: Forum Members
Posts: 5,
Visits: 26
|
Sorry to be a pest, but would that randomise the presentations of the pairs for each participant and also make sure the multiple presentations of the one sentence don't appear too closely together?
|
|
Group: Administrators
Posts: 12K,
Visits: 98K
|
It does both. Run the code and see for yourself.
|
|
Group: Forum Members
Posts: 5,
Visits: 26
|
oh okay, thank you, I will give it a go
|