Millisecond Forums

#1: I must assume you only want to run the *color naming* portion of the script. The *word naming* portion would not make any sense since the string "XXXXXX" is not pronounceable. Correct?

#2: If so (and if i understood your description correctly), all you need to do then is create separate <item> elements for each color. I.e. instead of

<item colors>
/1 ="         red         "
/2 ="        green        "
/3 ="        blue         "
/4 ="        black        "
/5 ="       yellow        "
</item>

<text red>
/items=colors
/color = (255,0,0)
</text>

<text blue>
/items=colors
/color = (0,0,255)
</text>
...

you set up

<item colors_red>
/1 ="        XXXXX         "
/2 ="        green        "
/3 ="        blue         "
/4 ="        black        "
/5 ="       yellow        "
</item>

<item colors_blue>
/1 ="         red         "
/2 ="        green        "
/3 ="        XXXXX         "
/4 ="        black        "
/5 ="       yellow        "
</item>
...
<text red>
/items=colors_red
/color = (255,0,0)
</text>

<text blue>
/items=colors_blue
/color = (0,0,255)
</text>
...

What were previously "congruent" trials are now "control" trials.

Thank you very much, Dave. If I knew where you lived, I'd order you a fruit basket.

1. Correct--I deleted the word naming portion because I only need color naming.

2. This worked perfectly. A part I didn't mention is that some recommend that the string length of control trials match the character length of the word, but this was easy to add. For example, yellow printed in yellow became ****** and red printed in red became ***.

I have to add more trials and increase the proportion of control trials, but I see other topics on that in the forum that will help.

To increase the proportion of "control" (formerly "congruent") trials, it would be easiest to set up a bunch of <list> elements and use those for item selection. Let's look at <trial red> as an example:

<trial red>
/ontrialbegin = [values.color = "red"]
/stimulustimes = [0=red]
/posttrialpause = 250
/validresponse = ("yellow" "green" "blue" "black" "red")
/correctresponse = ("red")
/ontrialend = [if (text.red.currentitemnumber == 1) {
                        values.count_congruent += 1;
                        values.congruence = 1}
                else {
                        values.count_incongruent += 1;
                        values.congruence = 2}]
/ontrialend = [if (text.red.currentitemnumber == 1 && trial.red.correct) {
                        values.countcorrect_congruent += 1;
                        values.sumrt_congruent += trial.red.latency}]
/ontrialend = [if (text.red.currentitemnumber != 1 && trial.red.correct) {
                        values.countcorrect_incongruent += 1;
                        values.sumrt_incongruent += trial.red.latency}]

</trial>

As you can see it displays the stimulus element <text red> with the below items. Whenever the 1st item is selected (the Xs), the trial is recorded as "control" (formerly "congruent") as per the /ontrialend logic highlighted above.

<item colors_red>
/1 ="        XXXXX         "
/2 ="        green        "
/3 ="        blue         "
/4 ="        black        "
/5 ="       yellow        "
</item>
...
<text red>
/items=colors_red
/color = (255,0,0)
</text>

What that effectively means is that 1 in every 5 instances (20%) of <trial red> will be "control" / "congruent".

Now, let's say you want to increase the proportion of "control" / "congruent" instances to 50% (or 4 out of 8). To do this, you could set up

<list red_items>
/ items = (1,1,1,1,2,3,4,5)
/ selectionmode = random
</list>

which contains item #1 four times, and use that list for item selection in <text red>:

<text red>
/items=colors_red
/color = (255,0,0)
/select = list.red_items.nextvalue
</text>

The changes for the other color <trial> and <text> elements (<trial green> / <text green>, <trial blue> / <text blue>) would be analogous. Only the item numbers differ in each case.