Summary data output


Summary data output

Author
Message
inquisituser22
inquisituser22
New Member
New Member (38 reputation)New Member (38 reputation)New Member (38 reputation)New Member (38 reputation)New Member (38 reputation)New Member (38 reputation)New Member (38 reputation)New Member (38 reputation)New Member (38 reputation)

Group: Forum Members
Posts: 5, Visits: 13
Hello,
We have an experiment where each participant's individual responses per item are saving on different rows of a spreadsheet in the output file. We are looking for recommendations about how to efficiently save this as mean scores with one line per participant in the spreadsheet instead.

So far my best idea is to save as a .dat file, then open in SPSS and take averages from there.

Thanks very much!
Dave
Dave
Supreme Being
Supreme Being (428K reputation)Supreme Being (428K reputation)Supreme Being (428K reputation)Supreme Being (428K reputation)Supreme Being (428K reputation)Supreme Being (428K reputation)Supreme Being (428K reputation)Supreme Being (428K reputation)Supreme Being (428K reputation)

Group: Administrators
Posts: 8.9K, Visits: 38K
inquisituser22 - Friday, June 29, 2018
Hello,
We have an experiment where each participant's individual responses per item are saving on different rows of a spreadsheet in the output file. We are looking for recommendations about how to efficiently save this as mean scores with one line per participant in the spreadsheet instead.

So far my best idea is to save as a .dat file, then open in SPSS and take averages from there.

Thanks very much!

> So far my best idea is to save as a .dat file, then open in SPSS and take averages from there.

That's definitely something you can do, it's the traditional way of processing and preparing reaction time data for further analysis.

Beyond that, you can have Inquisit create an additional single-line data file containing summary statistics per the <summarydata> element. The functionality to actually calculate the summary statistics of interest (here: some means) you would have to build into your script. As a simple example, consider a script where you have two types of trials A and B. You want to calculate the mean reaction time for each trial type -- mean_rt_a and mean_rt_b -- only considering correct responses, and log that as summary information. The code to do that would look like this:

<block example>
/ trials = [1-10 = noreplace(a_trial, b_trial)]
</block>

// counts of correct responses for trial A and B
<values>
/ n_correct_a = 0
/ n_correct_b = 0
</values>

<trial a_trial>
/ ontrialend = [
    if (trial.a_trial.correct) {
        list.correct_rts_a.appenditem(trial.a_trial.latency);
        values.n_correct_a += 1;
    }
]
/ stimulusframes = [1=a_stim]
/ validresponse = ("a", "b")
/ correctresponse = ("a")
</trial>

<trial b_trial>
/ ontrialend = [
    if (trial.b_trial.correct) {
        list.correct_rts_b.appenditem(trial.b_trial.latency);
        values.n_correct_b += 1;
    }
]
/ stimulusframes = [1=b_stim]
/ validresponse = ("a", "b")
/ correctresponse = ("b")
</trial>

//will store the RTs of correct responses to trial A
<list correct_rts_a>
</list>
//will store the RTs of correct responses to trial B
<list correct_rts_b>
</list>

<text a_stim>
/ items = a_items
</text>

<text b_stim>
/ items = b_items
</text>

<item a_items>
/ 1 = "A_1"
/ 2 = "A_2"
/ 3 = "A_3"
/ 4 = "A_4"
/ 5 = "A_5"
</item>

<item b_items>
/ 1 = "B_1"
/ 2 = "B_2"
/ 3 = "B_3"
/ 4 = "B_4"
/ 5 = "B_5"
</item>

<summarydata>
/ columns = (script.startdate script.starttime script.subjectid script.groupid script.elapsedtime
    values.n_correct_a list.correct_rts_a.mean values.n_correct_b list.correct_rts_b.mean)
/ separatefiles = true
</summarydata>



GO


Reading This Topic


Login
Existing Account
Email Address:


Password:


Social Logins

Select a Forum....






Millisecond Forums


Search