Millisecond Forums

Branching and the like (/branch, /skip) works at the <surveypage> level, not at the level of individual question elments <e.g. <radiobuttons>, <checkboxes>, etc.). In your case you'd have one <surveypage> that contains the gender question element. Then /branch to a different <surveypage> containing the follow-up questions if a subject answers 'female':

<surveypage demographics>
/ questions = [1=gender; 2=age]
/ branch = [if(radiobuttons.gender.response=="female")surveypage.femalefollowup]
</surveypage>

<surveypage femalefollowup>
/ questions = [1=stuff]
</surveypage>

<radiobuttons gender>
/ caption = "You are"
/ options = ("female","male")
</radiobuttons>

<textbox age>
/ caption = "Your age"
</textbox>

<textbox stuff>
/ caption = "You should only see this if you indicated 'female':"
</textbox>

<survey mysurvey>
/ pages = [1=demographics]
</survey>

Alternatively, you can use the /skip attribute. I.e. if the subject answers "male", skip the follow-up page:

<surveypage demographics>
/ questions = [1=gender; 2=age]
</surveypage>

<surveypage femalefollowup>
/ skip = [radiobuttons.gender.response=="male"]
/ questions = [1=stuff]
</surveypage>

<radiobuttons gender>
/ caption = "You are"
/ options = ("female","male")
</radiobuttons>

<textbox age>
/ caption = "Your age"
</textbox>

<textbox stuff>
/ caption = "You should only see this if you indicated 'female':"
</textbox>

<survey mysurvey>
/ pages = [1=demographics; 2=femalefollowup]
</survey>

Regards,

~Dave

It's now working just as I wanted it to, thanks loads!

One minor thing: for ethics approval, questions must be optional, thus I have required = false.  I'm using the skip option, and for the pp that skip the gender question, they still get the female followup questions.  I want them to skip it as well.  I tried:

/ skip = [radiobuttons.gender.response=="noresponse"]

but that didn't work.  What do I need to enter as the response?

/ skip = [radiobuttons.gender.response!="female"]

where != is a logical "not". BTW, that's the only /skip you need as it covers both cases ("male" response or no response).

~Dave

Hey Dave,

Don't use /skip in this case, use /branch.<surveypage demographics>
/ branch = [if (radiobuttons.gender.response=="female") surveypage.femalefollowup]
/ questions = [1=gender; 2=age]
</surveypage>

<surveypage femalefollowup>
/ questions = [1=stuff]
</surveypage>

<surveypage funnybunny>
/ questions = [1=stuffpuff]
</surveypage>

<radiobuttons gender>
/ caption = "You are"
/ options = ("female","male")
</radiobuttons>

<textbox age>
/ caption = "Your age"
</textbox>

<textbox stuff>
/ caption = "Because you're a woman, write stuff here:"
</textbox>

<textbox stuffpuff>
/ caption = "and now press the back button to get back to the demographics page…unfortunately it will lead you to the femalefollowup page as a male and female"
</textbox>

<survey mysurvey>
/ pages = [1=demographics; 2=funnybunny]
</survey>