Creating Trials

The IAT task requires that we create trial elements that present the stimuli representing the target and attribute categories and gather classification responses to those stimuli. There are six types of trials used in this task depending on which category of stimulus is presented and which response key is assigned as the correct classification of the category.

First, let's define trials involving good words:

<trial attributeA>  
/ validresponse = ("E", "I")
/ correctresponse = ("E")
/ stimulusframes = [1 = attributeA]
/ posttrialpause = 250
</trial>

The trial element's name is attributeA, which is also the name of the text element containing the good attribute words. The validresponse command indicates that participants may respond by pressing the "E" or the "I" key on the keyboard. The "E" key is considered a correct response as specified by the correctresponsecommand. The posttrialpause attribute specifies that after the response, Inquisit inserts a 250 ms pause before advancing to the next trial.

The definition of the other trial elements are the similar to attributeA , differing only in the type of stimulus presented and the response that's considered correct.

Here's the definition of trials with bad words where "I" is a correct response:

<trial attributeB>  
/ validresponse = ("E", "I")
/ correctresponse = ("I")
/ stimulusframes = [1 = attributeB]
/ posttrialpause = 250
</trial>

Next come trials with insect pictures classified with the "E" key:

<trial targetBleft>  
/ validresponse = ("E", "I")
/ correctresponse = ("E")
/ stimulusframes = [1 = targetB]
/ posttrialpause = 250
</trial>

Trials with insect pictures classified with the "I" key:

<trial targetBright>  
/ validresponse = ("E", "I")
/ correctresponse = ("I")
/ stimulusframes = [1 = targetB]
/ posttrialpause = 250
</trial>

Trials with flower pictures classified with the "E" key:

<trial targetAleft>  
/ validresponse = ("E", "I")
/ correctresponse = ("E")
/ stimulusframes = [1 = targetA]
/ posttrialpause = 250
</trial>

Trials with flower pictures classified with the "I" key:

<trial targetAright>  
/ validresponse = ("E", "I")
/ correctresponse = ("I")
/ stimulusframes = [1 = targetA]
/ posttrialpause = 250
</trial>

The trials above capture the different combinations of stimulus category and correct response in the IAT. Our script will define one additional trial used to present task instructions to participants. This trial is defined as follows:

<trial instructions>  
/ stimulustimes = [1=instructions, spacebar]
/ correctresponse = (" ")
/ errormessage = false
/ recorddata = false
</trial>

The stimulustimes attribute specifies that the trial presents two text stimuli, one called "instructions" which contains the IAT task instructions, and another called "spacebar" which informs the participant they can press the spacebar to advance to the next trial. The correctresponse attribute indicates that pressing the spacebar key is the only correct response, and since the trial contains no validresponse definition, the spacebar is the only valid response as well. No error feedback is presented on this trial. Since the trial does not gather any data of interest, we've set recorddata to false so that the data for this trial (e.g., response, latency, stimuli, etc.) are not recorded to the data file. This helps us keep our data files concise and clean, and it saves us the trouble of having to filter out this data later.


Creating Instructions Creating Blocks