Two simultaneous likert scales per trial


Author
Message
Nesard
Nesard
Esteemed Member (1.7K reputation)Esteemed Member (1.7K reputation)Esteemed Member (1.7K reputation)Esteemed Member (1.7K reputation)Esteemed Member (1.7K reputation)Esteemed Member (1.7K reputation)Esteemed Member (1.7K reputation)Esteemed Member (1.7K reputation)Esteemed Member (1.7K reputation)
Group: Forum Members
Posts: 17, Visits: 153
Hi,

I need to show one image every trial with to likert scales for two different questions on the same screen. Is it possible to do this?

Besides, I have three different types of images (Positive Emotional State, Neutral Emotional State and Negative Emotional State). I need to show these images in random order, being sure that more than two images of the same emotional state will never be displayed consecutively.

This is de code I have so far:

<values>
/responsestoring = false
</values>

<defaults>
/screencolor = (255, 255, 255)
/font = ("Helvetica", -16, 700, 0, 49)
/txbgcolor=(255,255,255)
</defaults>

<expt>
/ preinstructions = (intro)
/ blocks = [1 = MSDFE]
/ postinstructions = (end)
</expt>

<block MSDFE>
/ preinstructions = (instruccionesMSDFE)
/trials = [1-15 = likertMSDFE]
/recorddata = true
/ bgstim = (comoCreeTxt)
</block>

<likert likertMSDFE>
/ anchors = [1="Negativo"; 5 = "Neutro"; 9="Positivo"]
/ stimulusframes = [1-15 = pictureMSDFE]
/ mouse = false
/ numpoints = 9
/ position = (50, 90)
</likert>

<text comoCreeTxt>
/items = comoCree
/position = (50, 10)
</text>

<item comoCree>
/1 = "¿Cómo cree que se está sintiendo esta persona?"
</item>

<picture pictureMSDFE>
/items = item_MSDFE
/select = noreplace
/size = (60%, 60%)
/position = (50%, 50%)
</picture>

<item item_MSDFE>
/1 = "MSDFE1/negativoHombre-414M.tif"
/2 = "MSDFE1/negativoHombre-425M.tif"
/3 = "MSDFE1/negativoHombre-426M.tif"
/4 = "MSDFE1/negativoMujer-274.tif"
/5 = "MSDFE1/negativoMujer-453M.tif"
/6 = "MSDFE1/neutralHombre-20.tif"
/7 = "MSDFE1/neutralHombre-23.tif"
/8 = "MSDFE1/neutralMujer-27.tif"
/9 = "MSDFE1/neutralMujer-46M.tif"
/10 = "MSDFE1/neutralMujer45M.tif"
/11 = "MSDFE1/positivoHombre-422M.tif"
/12 = "MSDFE1/positivoHombre-442M.tif"
/13 = "MSDFE1/positivoMujer-452M.tif"
/14 = "MSDFE1/positivoMujer-462M.tif"
/15 = "MSDFE1/positivoMujer-472M.tif"
</item>

**************** INSTRUCTION DEFINITION AND INSTRUCTION PAGES ******************

<instruct>
/windowsize = (65%, 85%)
/ fontstyle = ("Helvetica", 2.5%, false, false, false, false, 5, 1)
/ txcolor = (black)
/ finishlabel = "Presiona la tecla Enter continuar"
/ nextkey = (28)
/ nextlabel = "Presiona la tecla Enter para continuar"
/ prevkey = (57)
/ prevlabel = "Presiona la barra espaciadora para volver atrás"
</instruct>

<page intro>
El objetivo de este experimento es determinar tu capacidad de atención a una serie de estímulos visuales que verás a continuación.^^

Sin embargo, antes de continuar te haremos algunas preguntas. Recuerda que todas las respuestas son anónimas. Así que te puedes sentir en libertad de marcar las respuestas
que realmente describen como te sientes. Ademas tus respuestas son confidenciales y te será asignado un código que no estará relacionado con tu nombre.^^

Cuando estés listo, presiona la tecla Enter para comenzar.
</page>

<page end>
Aquí termina el experimento. !Gracias por particiar!
</page>

<page instruccionesMSDFE>
A continuación verás una serie de fotografías de diferentes personas. Deberás indicar como crees que se están sintiendo según su expresión facial.
Por favor asigna un número entre 1 y 9 a cada imagen usando la escala que se encuentra en la parte inferior de la pantalla.^^

Cuando hayas decidido tu respuesta, marca la opción correspondiente usando los números del teclado, y después presiona Enter.^^

"1" significa ESTADO EMOCIONAL MUY NEGATIVO^^
"2" significa ESTADO EMOCIONAL MODERADAMENTE NEGATIVO^^
"3" significa ESTADO EMOCIONAL POCO NEGATIVO^^
"4" significa ESTADO EMOCIONAL NEUTRO PERO CERCANO A NEGATIVO^^
"5" significa ESTADO EMOCIONAL TOTALMENTE NEUTRO^^
"6" significa ESTADO EMOCIONAL NEUTRO PERO CERCANO A POSITIVO^^
"7" significa ESTADO EMOCIONAL POCO POSITIVO^^
"8" significa ESTADO EMOCIONAL MODERADAMENTE POSITIVO^^
"9" significa ESTADO EMOCIONAL MUY POSITIVO^^^^

Avanza tan rápido como puedas respondiendo con la primer impresión que te genere. Avanzar muy lento o pensar demasiado tu respuesta generará resultados difíciles de interpretar.^^
</page>

<data>
/ file = "experimentoPiloto.iqdat"
/ columns = [build, date, time, subject, group, blockcode, blocknum, trialcode, trialnum,stimulusitem, latency, response]
/ separatefiles = true
</data>

Thanks.


Dave
Dave
Supreme Being (782K reputation)Supreme Being (782K reputation)Supreme Being (782K reputation)Supreme Being (782K reputation)Supreme Being (782K reputation)Supreme Being (782K reputation)Supreme Being (782K reputation)Supreme Being (782K reputation)Supreme Being (782K reputation)
Group: Administrators
Posts: 10K, Visits: 51K
> I need to show one image every trial with to likert scales for two different questions on the same screen. Is it possible to do this?

If you need to display several likert-like questions simultaneously, you cannot use <likert> trials. You need to set up <surveypage>s containing e.g. two <radiobuttons> elements instead. A <surveypage> is a special type of <trial>, so you can run them via a <block> just like an other <trial>-type element (<trial>, <likert>, <openended>).

> I need to show these images in random order, being sure that more than two images of the same emotional state will never be
> displayed consecutively.

Set up three <trial>-type elements (see above), one for each emotional category. You might have something like

<surveypage positive>
...
</surveypage>

to display the 5 "positive" images, and

<surveypage neutral>
...
</surveypage>

<surveypage negative>
...
</surveypage>

for the neutral and negative stimuli respectively.

Then set up a <list> imposing the selection constraint (no more than two in a row) via /maxrunsize:

<list triallist>
/ items = (surveypage.positive, surveypage.neutral, surveypage.negative)
/ poolsize = 15
/ maxrunsize = 2
</list>

Use that list for trial-selection in your <block>:

<block MSDFE>
/ trials = [1-15 = list.triallist]
...
</block>

GO

Merge Selected

Merge into selected topic...



Merge into merge target...



Merge into a specific topic ID...




Reading This Topic

Explore
Messages
Mentions
Search