Millisecond Forums

Hi,


I need to modify the effective priming example in your website by adding an EEG tirgir with at the time of stimulus presentation (prime and target) the EEG signal should to be different for the target and the prime so i can know which is which is this possible and how i can do that . please note that i am have little experiance with Inquisit. the script is below.

Than you

---------------------------------------------------------------------------------------
*** DEFAULTS *****
---------------------------------------------------------------------------------------           

<defaults>
/ screencolor = (0, 0, 0)
/ font = ("Arial", -20, 400, 0, 34)
/ txbgcolor = (0, 0, 0)
/ txcolor = (255,255,255)
/ inputdevice = keyboard
</defaults>

<data>
/ columns = [date time subject trialcode trialnum trialdata trialdata trialdata latency response]
</data>

------------------------------------------------------------------------------------
*** TEXS AND TARGETS *****
------------------------------------------------------------------------------------

<text positive>
/ select = noreplace
/ position = (93,50)
/ numitems = 1
/ items = positive
/ font = ("Arial", -16, 700, 0, 49)
/ txbgcolor = (0, 0, 0)
/ color = (255,255,255)
</text>

<item positive>
/1 = "positive"
</item>

<text negative>
/ select = noreplace
/ position = (5,50)
/ numitems = 1
/ items = negative
/ font = ("Arial", -16, 700, 0, 49)
/ txbgcolor = (0, 0, 0)
/ color = (255,255,255)
</text>

<item negative>
/1 = "negative"
</item>

<text positive_adjectives>
/ select = noreplace
/ position = (50,50)
/ numitems = 10
/ items = positive_adjectives
/ font = ("Arial", -20, 700, 0, 49)
/ txbgcolor = (0, 0, 0)
/ color = (255,255,255)
</text>


<item positive_adjectives>
/1 = "appealing"
/2 = "attractive"
/3 = "charming"
/4 = "delightful"
/5 = "desirable"
/6 = "fabulous"
/7 = "favorable"
/8 = "likable"
/9 = "nice"
/10 = "pleasant"
</item>

<text negative_adjectives>
/ select = noreplace
/ position = (50,50)
/ numitems = 10
/ items = negative_adjectives
/ font = ("Arial", -20, 700, 0, 49)
/ txbgcolor = (0, 0, 0)
/ color = (255,255,255)
</text>


<item negative_adjectives>
/1 = "annoying"
/2 = "awful"
/3 = "disturbing"
/4 = "horrible"
/5 = "inferior"
/6 = "irritating"
/7 = "nasty"
/8 = "offensive"
/9 = "repulsive"
/10 = "rotten"
</item>


<text objects>
/ select = noreplace
/ erase = true(0,0,0)
/ position = (50,50)
/ numitems = 16
/ items = objects
/ font = ("Arial", -20, 700, 0, 49)
/ txbgcolor = (0, 0, 0)
/ color = (255,255,255)
</text>

<item objects>
/1 = "aquarium"
/2 = "baby"
/3 = "cake"
/4 = "chocolate"
/5 = "eagle"
/6 = "Friday"
/7 = "parade"
/8 = "silk"
/9 = "divorce"
/10 = "hangover"
/11 = "litter"
/12 = "radiation"
/13 = "recession"
/14 = "toothache"
/15 = "virus"
/16 = "weeds"
</item>

<text target>
/ numitems = 1
/ items = target
/ font = ("Arial", -20, 700, 0, 49)
/ txbgcolor = (0, 0, 0)
/ color = (255,255,255)
/ position = (50, 50)
</text>

<item target>
/1 = "*"
</item>

<shape erase>
/ position = (50, 50)
/ color= (0, 0, 0)
/ size= (100, 250)
</shape>


------------------------------------------------------------------------------------
*** INSTRUCTION PAGES *****
------------------------------------------------------------------------------------

<instruct>
/ nextkey = (" ")
/ lastlabel = "Press the spacebar to continue"
/ nextlabel = "Press the spacebar to continue"
/ font = ("Arial", -18, 400, 0, 34)
/ screencolor = (0,0,0)
/ txcolor = (255,255,255)
</instruct>

<page welcome>
^^^^
                     Welcome to the Lexical Decision Experiment.
</page>

<page instruction>

Directions: In each trial a memory word will be flashed on the screen followed by an adjective. Your task is to indicate as quickly as possible whether the adjective has a positive or negative connotation and after that to read the memory word aloud.
^^If the adjective has a positive connotation press "q".^
If the adjective has a positive connotation press "p".
 
</page>

<page end>
^^
This is the end. Thank you for participating.
</page>


------------------------------------------------------------------------------------
*** PICTURE PRIMING TRIALS *****
------------------------------------------------------------------------------------

<trial series>
/ pretrialpause = 2000
/ validresponse = (16,25)
/ stimulustimes = [10=target; 2000 =objects;2200=erase; 2300=noreplace(positive_adjectives,negative_adjectives); ]
/ trialdata = [objects,positive_adjectives,negative_adjectives]
</trial>



------------------------------------------------------------------------------------
*** BLOCKS *****
------------------------------------------------------------------------------------

<block series>
/preinstructions =(instruction)
/ bgstim = (positive,negative)
/ trials = [1-16 =series]
</block>


------------------------------------------------------------------------------------
*** EXPT PRIMING TRIALS *****
------------------------------------------------------------------------------------

<expt>
/ blocks = [1=series]
/ preinstructions = (welcome)
/ postinstructions = (end)
</expt>

You need to use Inquisit's <port> element to send signals to your EEG device using the computer's parallel port. The <port> element is treated just like any other stimulus (text, picture, etc.) in Inquisit. So, first define two <port> stimuli in your script; one for the prime, another one for the target:

<port primesignal>
/ port = LPT1
/ subport =
data
/ items = ("00000001")
/ erase = "00000000"
</port>

<port targetsignal>
/ port = LPT1
/ subport =
data
/ items = ("00000010")
/ erase = "00000000"
</port>

Now, simply modify your <trial> element to present the signals along with the prime and target stimuli:

<trial series>
/ pretrialpause = 2000
/ validresponse = (16,25)
/ stimulustimes = [10=target; 2000 =objects, primesignal; 2200=erase; 2300=noreplace(positive_adjectives,negative_adjectives), targetsignal]
/ trialdata = [objects,positive_adjectives,negative_adjectives]
</trial>

That should do the trick.

Best,
~Dave

Hi,

Thank you Dave for your help can i ask you for tow more advices. As i am using large number of picture in this expiration ( i will make the changes latter) that could be a exhausting  for participants so i need to to pause the experiment when user feel tired. The other thing is as i am going to use pictures with tow categories of words (positive and negative) i need to make sure that each picture has been presented at least one time with positive each positive word and one time with each negative word in randomly order.


Best Wishes

Both things certainly can be done with Inquisit.

(1) Pausing the experiment:
I suspect that you want to let participants decide by themselves when to take a break during the experiment. One way to do this is to add a /branch command to your priming trials that invokes a 'pause' trial when a subject presses a certain key on the keyboard (e.g. 'p' for 'pause').

(2) Making sure that each picture is presented with both negative and positive words:
This can also be done. There certainly are multiple approaches to this. I recommend studying the topics pertaining to item selection in the Inquisit help-file. Also, this will be much easier to address once you have your script ready up to this point.

Hope this helps,
~Dave

Hi ,

Thank you Dave again for your kindness and help and sorry for bothering you again. I sorry i did not understand your solution for number 1, i read about /branch command however i did not find any thing related to pausing the experiment can you please explain? please be aware that i am a very beginner in Inquisit. As for the second point the script will be the same as you can see above wih view changes ( pictures unsted of text) and the timing.  If you can please write the changes i will be thankful.


Best Wishes
Shaikh

I'm sorry, but you'll have to be more specific about what you're trying to do and which parts you can't get to work. Additionally you didn't answer my (implicit) question whether you want participants to be able to 'pause' the experiment whenever they want. If you wanted to follow the approach outlined in my previous post, you will have to add an additional <trial> element to the script (named <trial pause>, for example) and add some more commands to the existing <trial series> element. Adding the following to the script will pause the experiment when a subject presses the spacebar. Note that you will not have meaningful data for the specific priming trial that a participant decides to take a break in.

<trial series>
/ pretrialpause = 2000
/ validresponse = (16,25,57)
/ stimulustimes = [10=target; 2000 =objects;2200=erase; 2300=noreplace(positive_adjectives,negative_adjectives)]
/ trialdata = [objects,positive_adjectives,negative_adjectives]
/ responsetrial = (57, pause)
</trial>

<trial pause>
/ stimulusframes = [1=pause]
/ validresponse = (anyresponse)
</trial>

<text pause>
/ items = ("experiment paused - press any key to continue")
/ txcolor = (255, 255, 255)
/ position = (50, 50)
</text>

I don't have the time to write up all the changes necessary as this would probably amount to writing the whole script for you (note that I *do not* work for Millisecond Software - I am just a regular Inquisit user trying to help other users like you) - and ultimately this wouldn't help you in terms of learning how to use the software. So, in order to get started with Inquisit and learning how to design experiments with it, I recommend you to go through the tutorials provided in the Inquisit help-file. That should give you a sound foundation for writing your own and modifying existing scripts (like the affective priming example discussed herein).

Please feel free to ask any additional questions, but please be more specific about the issues you are experiencing.

All the best,
~Dave

By the way, it just occured to me that it might be better to work with the '/ pretrialsignal' attribute in your priming trials. This would require subjects to press a certain key on the computer's keyboard before each priming trial. Thus, they could take a break whenever they feel like *and* you wouldn't loose any data. Just an idea...

Best,
~Dave