Randomizing Image Selection from Categories and Randomizing Survey Questions Under Images


Randomizing Image Selection from Categories and Randomizing Survey...

Author
Message
ashleym
ashleym
Expert
Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)

Group: Forum Members
Posts: 15, Visits: 35
Hi,

I am setting up a brand new script and have not done anything like this before, so I am wondering if someone might be able to help get me started with a short example. This may be a very basic request, but I haven't used Inquisit much. I need to do a few key things:

1. I need to present participants with 10 random images (without replacement) across four different image categories. I have four image categories (RM, RL, UM, and UL), each containing 30 images. I want different participants to randomly receive 10 images from each of the four categories, so they are seeing a total of 40 images, 10 from each category.
2. Related to point 1 above, is it possible to randomly order selection from ACROSS the categories? So, for example, can the first image be selected from the RM category, and then the next image from the UL category, and so on? So participants aren't receiving 10 random images from the first category, followed by the second, and third, and then fourth.
3. Finally, I need each randomly presented image to appear on several screens in a row, while participants answer one question per page about each image.

So something like this:

Page 1:
Randomly selected image 1 from RM category
To what extent is this image attractive?
Not at all to extremely

Page 2:
Randomly selected image 1 from RM category
To what extent is this image pleasing to view?
Not at all to extremely

Page 3: 
Randomly selected image 1 from RM category
To what extent is this image . . . ?
Not at all to extremely

Page 4:
Randomly selected image 2 from UL category
To what extent is this image attractive?
Not at all to extremely

Page 6:
Randomly selected image 2 from UL category
To what extent is this image please to view?
Not at all to extremely

And so on.

Ideally, the selection of the images would be random both within and across categories AND the presentation of the questions underneath each image also would be randomized.

If someone could get me started on this, that would be amazing...or perhaps I can be directed to a relevant post or manual or something. Any help is greatly appreciated!
Thank you (SO MUCH) in advance!!!! 


Dave
Dave
Supreme Being
Supreme Being (749K reputation)Supreme Being (749K reputation)Supreme Being (749K reputation)Supreme Being (749K reputation)Supreme Being (749K reputation)Supreme Being (749K reputation)Supreme Being (749K reputation)Supreme Being (749K reputation)Supreme Being (749K reputation)

Group: Administrators
Posts: 9.9K, Visits: 49K
ashleym - 11/30/2019
Hi,

I am setting up a brand new script and have not done anything like this before, so I am wondering if someone might be able to help get me started with a short example. This may be a very basic request, but I haven't used Inquisit much. I need to do a few key things:

1. I need to present participants with 10 random images (without replacement) across four different image categories. I have four image categories (RM, RL, UM, and UL), each containing 30 images. I want different participants to randomly receive 10 images from each of the four categories, so they are seeing a total of 40 images, 10 from each category.
2. Related to point 1 above, is it possible to randomly order selection from ACROSS the categories? So, for example, can the first image be selected from the RM category, and then the next image from the UL category, and so on? So participants aren't receiving 10 random images from the first category, followed by the second, and third, and then fourth.
3. Finally, I need each randomly presented image to appear on several screens in a row, while participants answer one question per page about each image.

So something like this:

Page 1:
Randomly selected image 1 from RM category
To what extent is this image attractive?
Not at all to extremely

Page 2:
Randomly selected image 1 from RM category
To what extent is this image pleasing to view?
Not at all to extremely

Page 3: 
Randomly selected image 1 from RM category
To what extent is this image . . . ?
Not at all to extremely

Page 4:
Randomly selected image 2 from UL category
To what extent is this image attractive?
Not at all to extremely

Page 6:
Randomly selected image 2 from UL category
To what extent is this image please to view?
Not at all to extremely

And so on.

Ideally, the selection of the images would be random both within and across categories AND the presentation of the questions underneath each image also would be randomized.

If someone could get me started on this, that would be amazing...or perhaps I can be directed to a relevant post or manual or something. Any help is greatly appreciated!
Thank you (SO MUCH) in advance!!!! 



Here's an example implementing two of the four categories, RM and RL. The extension to the full four categories should be straightforward:

<values>
/ qcount = 0
/ RMitemnumber = 1
/ RLitemnumber = 1
</values>

<block example>
/ trials = [1-20 = noreplace(RM, RL)]
</block>

//RM
<trial RM>
/ ontrialbegin = [
values.RMitemnumber = list.RMitems.nextindex;
values.qcount = 0;
]
/ trialduration = 0
/ recorddata = false
/ branch = [
list.RMtrials.nextvalue;
]
</trial>

<list RMtrials>
/ items = (likert.RMq1, likert.RMq2, likert.RMq3)
</list>

<likert RMq1>
/ ontrialbegin = [
values.qcount += 1;
]
/ stimulusframes = [1=RM, q1]
/ numpoints = 5
/ anchorwidth = 8%
/ anchors = [1="Not at all"; 5="Extremely"]
/ position = (50%, 90%)
/ branch = [
if (values.qcount < 3) list.RMtrials.nextvalue;
]
</likert>

<likert RMq2>
/ ontrialbegin = [
values.qcount += 1;
]
/ stimulusframes = [1=RM, q2]
/ numpoints = 5
/ anchorwidth = 8%
/ anchors = [1="Not at all"; 5="Extremely"]
/ position = (50%, 90%)
/ branch = [
if (values.qcount < 3) list.RMtrials.nextvalue;
]
</likert>

<likert RMq3>
/ ontrialbegin = [
values.qcount += 1;
]
/ stimulusframes = [1=RM, q3]
/ numpoints = 5
/ anchorwidth = 8%
/ anchors = [1="Not at all"; 5="Extremely"]
/ position = (50%, 90%)
/ branch = [
if (values.qcount < 3) list.RMtrials.nextvalue;
]
</likert>

<list RMitems>
/ poolsize = 30
</list>

<picture RM>
/ items = RMitems
/ select = values.RMitemnumber
/ size = (30%, 40%)
/ position = (50%, 50%)
</picture>

<item RMitems>
/ 1 = "rm_01.jpg"
/ 2 = "rm_02.jpg"
/ 3 = "rm_03.jpg"
/ 4 = "rm_04.jpg"
/ 5 = "rm_05.jpg"
/ 6 = "rm_06.jpg"
/ 7 = "rm_07.jpg"
/ 8 = "rm_08.jpg"
/ 9 = "rm_09.jpg"
/ 10 = "rm_10.jpg"
/ 11 = "rm_11.jpg"
/ 12 = "rm_12.jpg"
/ 13 = "rm_13.jpg"
/ 14 = "rm_14.jpg"
/ 15 = "rm_15.jpg"
/ 16 = "rm_16.jpg"
/ 17 = "rm_17.jpg"
/ 18 = "rm_18.jpg"
/ 19 = "rm_19.jpg"
/ 20 = "rm_20.jpg"
/ 21 = "rm_21.jpg"
/ 22 = "rm_22.jpg"
/ 23 = "rm_23.jpg"
/ 24 = "rm_24.jpg"
/ 25 = "rm_25.jpg"
/ 26 = "rm_26.jpg"
/ 27 = "rm_27.jpg"
/ 28 = "rm_28.jpg"
/ 29 = "rm_29.jpg"
/ 30 = "rm_30.jpg"
</item>

//RL
<trial RL>
/ ontrialbegin = [
values.RLitemnumber = list.RLitems.nextindex;
values.qcount = 0;
]
/ trialduration = 0
/ recorddata = false
/ branch = [
list.RLtrials.nextvalue;
]
</trial>

<list RLtrials>
/ items = (likert.RLq1, likert.RLq2, likert.RLq3)
</list>

<likert RLq1>
/ ontrialbegin = [
values.qcount += 1;
]
/ stimulusframes = [1=RL, q1]
/ numpoints = 5
/ anchorwidth = 8%
/ anchors = [1="Not at all"; 5="Extremely"]
/ position = (50%, 90%)
/ branch = [
if (values.qcount < 3) list.RLtrials.nextvalue;
]
</likert>

<likert RLq2>
/ ontrialbegin = [
values.qcount += 1;
]
/ stimulusframes = [1=RL, q2]
/ numpoints = 5
/ anchorwidth = 8%
/ anchors = [1="Not at all"; 5="Extremely"]
/ position = (50%, 90%)
/ branch = [
if (values.qcount < 3) list.RLtrials.nextvalue;
]
</likert>

<likert RLq3>
/ ontrialbegin = [
values.qcount += 1;
]
/ stimulusframes = [1=RL, q3]
/ numpoints = 5
/ anchorwidth = 8%
/ anchors = [1="Not at all"; 5="Extremely"]
/ position = (50%, 90%)
/ branch = [
if (values.qcount < 3) list.RLtrials.nextvalue;
]
</likert>

<list RLitems>
/ poolsize = 30
</list>

<picture RL>
/ items = RLitems
/ select = values.RLitemnumber
/ size = (30%, 40%)
/ position = (50%, 50%)
</picture>

<item RLitems>
/ 1 = "rl_01.jpg"
/ 2 = "rl_02.jpg"
/ 3 = "rl_03.jpg"
/ 4 = "rl_04.jpg"
/ 5 = "rl_05.jpg"
/ 6 = "rl_06.jpg"
/ 7 = "rl_07.jpg"
/ 8 = "rl_08.jpg"
/ 9 = "rl_09.jpg"
/ 10 = "rl_10.jpg"
/ 11 = "rl_11.jpg"
/ 12 = "rl_12.jpg"
/ 13 = "rl_13.jpg"
/ 14 = "rl_14.jpg"
/ 15 = "rl_15.jpg"
/ 16 = "rl_16.jpg"
/ 17 = "rl_17.jpg"
/ 18 = "rl_18.jpg"
/ 19 = "rl_19.jpg"
/ 20 = "rl_20.jpg"
/ 21 = "rl_21.jpg"
/ 22 = "rl_22.jpg"
/ 23 = "rl_23.jpg"
/ 24 = "rl_24.jpg"
/ 25 = "rl_25.jpg"
/ 26 = "rl_26.jpg"
/ 27 = "rl_27.jpg"
/ 28 = "rl_28.jpg"
/ 29 = "rl_29.jpg"
/ 30 = "rl_30.jpg"
</item>

<text q1>
/ items = ("To what extent is this image attractive?")
/ position = (50%, 80%)
</text>

<text q2>
/ items = ("To what extent is this image pleasing to view?")
/ position = (50%, 80%)
</text>

<text q3>
/ items = ("To what extent is this image ...?")
/ position = (50%, 80%)
</text>




ashleym
ashleym
Expert
Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)Expert (1K reputation)

Group: Forum Members
Posts: 15, Visits: 35
Wow, thank you so much for this!! I sincerely appreciate you taking the time to write this out for me. It works and this is amazing, THANK YOU!
GO


Reading This Topic


Login
Existing Account
Email Address:


Password:


Social Logins

Select a Forum....






Millisecond Forums


Search